Перемещение слайда от начала до конца раздела

Question

У меня есть макрос, который создает новый слайд в начале раздела моей презентации PowerPoint.

Есть ли способ заменить .MoveToSectionStart, который бы сдвинул слайд в конец?

Метод находится в Sub в конце, называемом Sub AddCustomSlide().

Private Function GetSectionNumber( _
        ByVal sectionName As String, _
        Optional ParentPresentation As Presentation = Nothing) As Long

    If ParentPresentation Is Nothing Then
        Set ParentPresentation = ActivePresentation
    End If

    GetSectionNumber = -1
    With ParentPresentation.SectionProperties
        Dim i As Long
        For i = 1 To .Count
            If .Name(i) = sectionName Then
                GetSectionNumber = i
                Exit Function
            End If
        Next i
    End With
End Function

Public Function GetLayout( _
    LayoutName As String, _
    Optional ParentPresentation As Presentation = Nothing) As CustomLayout

    If ParentPresentation Is Nothing Then
        Set ParentPresentation = ActivePresentation
    End If

    Dim oLayout As CustomLayout
    For Each oLayout In ParentPresentation.SlideMaster.CustomLayouts
        If oLayout.Name = LayoutName Then
            Set GetLayout = oLayout
            Exit For
        End If
    Next
End Function

Sub AddCustomSlide()

    Dim oSlides As Slides, oSlide As Slide
    Dim Shp As Shape
    Dim Sld As Slide

    Set oSlides = ActivePresentation.Slides
    Set oSlide = oSlides.AddSlide(oSlides.Count - 2, GetLayout("Processwindow"))
    oSlide.MoveToSectionStart GetSectionNumber("Main Process")

End Sub

Answer 1

Извините, такого метода нет. Вот как вставить один в конце:

Sub AddCustomSlide()
    Dim oSlides As Slides, oSlide As Slide
    Dim Shp As Shape
    Dim Sld As Slide
    Dim SecNum As Integer, SlideCount As Integer, FirstSecSlide As Integer

    Set oSlides = ActivePresentation.Slides
    Set oSlide = oSlides.AddSlide(oSlides.Count - 2, GetLayout("Processwindow"))
    SecNum = GetSectionNumber("Main Process")
    With ActivePresentation.SectionProperties
        SlideCount = .SlidesCount(SecNum)
        FirstSecSlide = .FirstSlide(SecNum)
    End With
    oSlide.MoveTo toPos:=FirstSecSlide + SlideCount - 1
End Sub