Можно ли объединить несколько ячеек в одну, а также пропустить пустые ячейки?

Question

Можно ли объединить ячейки в одну 'ячейку результата', одновременно пропуская пустую ячейку?

Ниже приведено изображение желаемого результата. В настоящее время мне нужно использовать = CONCATENATE, чтобы получить этот результат, но затем мне нужно через него go удалить все пустые ячейки вручную (с более чем 50 столбцами и 1000 строками это занимает много времени).

Также имеется ссылка на электронную таблицу для просмотра:

Таблица Excel

Answer 1

Использовать TEXTJOIN:

=TEXTJOIN(CHAR(10),TRUE,IF(A2:D2<>"",$A$1:$D$1&": "&A2:D2,""))

В зависимости от версии это может потребоваться подтвердить с помощью Ctrl-Shift-Enter вместо Enter при выходе из режима редактирования.

Answer 2

Используйте формулу

=CONCATENATE(IF(A3="","","Size: "&A3&CHAR(10)),IF(B3="","","Material: "&B3&CHAR(10)),IF(C3="","","Colour: "&CHAR(10)),IF(D3="","","Weight: "&D3))

Примечание: убедитесь, что у вас включен перенос текста в ячейки, содержащие разрывы строк.

Answer 3

Эта формула должна помочь вам:

=CONCATENATE(IF(NOT(ISBLANK(A2));CONCATENATE($A$1;":";" ";A2);"");CHAR(10);IF(NOT(ISBLANK(B2));CONCATENATE($B$1;":";" ";B2);"");CHAR(10);IF(NOT(ISBLANK(C2));CONCATENATE($C$1;":";" ";C2);"");CHAR(10);IF(NOT(ISBLANK(D2));CONCATENATE($D$1;":";" ";D2);""))

Взгляните на мою таблицу: Excel

Answer 4

Вы можете попробовать это:

IF(NOT(ISEMPTY(A2)), A$1 & ": " & A2 & CHAR(10), "") & IF(…

РЕДАКТИРОВАТЬ:

=IF(NOT(ISBLANK(A2)), A$1 & ": " & A2 & CHAR(10), "") & 
 IF(NOT(ISBLANK(B2)), B$1 & ": " & B2 & CHAR(10), "") & 
 IF(NOT(ISBLANK(C2)), C$1 & ": " & C2 & CHAR(10), "") &
 IF(NOT(ISBLANK(D2)), D$1 & ": " & D2, "") 

Все в одной строке. ISEMPTY - это вариант VBA функции ISBLANK для рабочих листов.