Как пользователю выбрать количество папок на рабочем столе, которые будут созданы с именами чисел c с использованием applecript?

Question

Я пытаюсь разрешить пользователю выбирать, сколько папок он хочет создать на рабочем столе. Желаемый формат файла: 00,01,02,03..10,11,12,13,14 ... 99. Я чувствую, что я близок к созданию папок, но я застрял. Любая помощь будет оценена!

set targetFolder to desktop
repeat
    set subCount to text returned of (display dialog "How many Folders?" default answer 1)
    try
        if subCount ≠ "" then
            subCount as integer
            exit repeat
        end if
    end try
end repeat

repeat with i from 1 to subCount
    tell application "Finder" to make new folder at targetFolder with properties {name:i}
end repeat

Answer 1

Ты рядом. Вообще говоря, лучше использовать System Events.app, чем Finder (Finder более требователен к спецификациям пути к файлу и время от времени склонен к зависанию), и если вы хотите, чтобы имена папок были заполнены нулями, вы должны преобразовать целое число индекса в строку.

repeat
    set subCount to text returned of (display dialog "How many Folders?" default answer 1)
    try
        set subCount to subCount as integer
        exit repeat
    on error
        display alert "The value must be an integer"
    end try
end repeat

tell application "System Events"
    repeat with idx from 1 to subCount
        make new folder at desktop folder with properties {name:my zeroPad(idx - 1)}
    end repeat
end tell

on zeroPad(a_num)
    return text -2 through -1 of ("0000" & a_num as string)
end zeroPad