Как мне найти самый длинный список в списке списков?

Question

У меня есть список списков, и мне нужно найти самый длинный из них. Если есть более одного с одинаковой длиной, это то же самое, которое он возвращает. Спасибо.

Answer 1

Вот общий предикат, который просматривает список, чтобы найти единственного члена, определенного данной целью.

select_element(Goal, [Head | Tail], Selected) :-
    select_element(Goal, Tail, Head, Selected).


select_element(_Goal, [], Selected, Selected).

select_element(Goal, [Head | Tail], Current, FinalSelected) :-
    call(Goal, Head, Current, Selected),
    select_element(Goal, Tail, Selected, FinalSelected).

Допустим, вы определяете предикат

get_bigger_number(N1, N2, N) :-
    N is max(N1, N2).

Теперь вы можете выполнить:

?- select_element(get_bigger_number, [5, 1, -2, 10, 3.2, 0], Selected).

Selected = 10

Итак, все, что вам нужно сделать сейчас, это определить предикат get_longer_list(L1, L2, L), и используйте его вместо get_bigger_number/3.

Конечно, использование общего предиката, подобного select_element/3, может быть не очень эффективным. Например, вам следует избегать расчета длины одного и того же списка несколько раз, потому что в Прологе это вычисление медленное (по крайней мере, если оно реализовано в Прологе стандартным способом).

Answer 2

Пожалуйста, примите во внимание мой подход.

longest([L], L) :-
   !.
longest([H|T], H) :- 
   length(H, N),
   longest(T, X),
   length(X, M),
   N > M,
   !.
longest([H|T], X) :-
   longest(T, X),
   !.

Тогда вы можете проконсультироваться с ним:

?- longest([[1]], N).
N = [1] ;

?- longest([[1],[2]], N).
N = [2] .

?- longest([[1],[2], [3,3,3], [2]], N).
N = [3, 3, 3] ;

?- longest([[1],[2], [3,3,3], [2]], N).
N = [3, 3, 3].

?- longest([[1],[2], [3,3,3], [2], [4,4,4,4]], N).
N = [4, 4, 4, 4] .

?- longest([[1],[2], [3,3,3], [2], [4,4,4,4]], N).
N = [4, 4, 4, 4] ;

Поздравил!

Answer 3

Вот еще один подход, который эффективен и прост для понимания. Идея состоит в том, чтобы найти длины всех списков в списке, использовать max_list, чтобы получить длину самого длинного списка, а затем найти список, который такой длинный. Преимущество состоит в том, что он возвращает все списки самой длинной длины.

lengths([],[]).
lengths([H|T], [LH|LengthsT]) :-
    length(H, LH),
    lengths(T, LengthsT).

lengthLongest(ListOfLists, Max) :-
    lengths(ListOfLists, Lengths),
    max_list(Lengths, Max).

longestList(ListOfLists, Longest) :-
    lengthLongest(ListOfLists, Len),
    member(Longest, ListOfLists),
    length(Longest, Len).

Answer 4

Мы определяем longest/2 на основе мета-предиката max_of_by/3, используемого совместно с length/2:

longest(Xss,Ys) :-
   max_of_by(Ys,Xss,length).

Примеры запросов:

?- longest([[1],[2]],Xs).      % we expect   multiple solutions
  Xs = [1]                
; Xs = [2].                    % we    _get_ multiple solutions

?- longest([[2,1,3],[7,5],[1,8,2,3,1],[2,7,1,4]],Xs).
Xs = [1,8,2,3,1].              % succeeds deterministically

Answer 5

% Correct again.

longest(LL,LX) :-
        findmax(Len,(append(_,[L|_],LL),length(L,Len)),MaxLen),
        append(_,[LX|_],LL),
        length(LX,MaxLen).

findmax(V,P,Max) :-
        findall(V,P,L),
        max(L,Max).

max([N],N) :- !.
max([N|R],Max) :-
        max(R,Max2),
        max3(N,Max2,Max).

max3(N,Max2,N) :- N > Max2,!.
max3(N,Max2,Max2).

Answer 6

Чтобы иметь длину самого длинного списка:

%sample: longest([[2,1,3],[7,5],[1,8,2,3,1],[2,7,1,4]],L,LEN).

longest([L], L, _) :-
   !.
longest([H|T], H, _) :-
   length(H, N),
   longest(T, X, N),
   length(X, M),
   N > M,
   !.
longest([_|T], X, LEN) :-
   length(X, LEN),
   longest(T, X, LEN),
   !.