Эти сценарии ожидают получения необязательного вывода (timeout -1 означает «нет времени ожидания»), и они могут отличать разные ответы, как этого требуют yum install и mysql_secure_installation. С #!/bin/expect -f в качестве shebang, сценарии могут быть выполнены, когда они были установлены на chmod +x.
A) Для начала, mariadb_yum.exp (требуется su или sudo):
#!/bin/expect -f
set timeout 30
if {[llength $argv] == 0} {
send_user "Usage: mariadb_yum.exp \[linux sudo password\]\n"
exit 1
}
set USERNAME "[exec whoami]"
set PASSWORD [lindex $argv 0];
# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/$USERNAME/mariadb_install.log"
spawn sudo yum -y install MariaDB-server
set yum_spawn_id $spawn_id
# On GCE it will never ask for a sudo password:
expect -ex "\[sudo\] password for $USERNAME: " {
exp_send "$PASSWORD\r"
}
expect {
# when the package was already installed
-ex "Nothing to do" {
send_user "package was already installed\n"
}
# when the package had been installed
-ex "Complete!" {
send_user "package had been installed\n"
}
}
expect eof
close $yum_spawn_id
exit 0
B) А затем mariadb_sec.exp (не требует sudo):
#!/bin/expect -f
set timeout 1
if {[llength $argv] == 0} {
send_user "Usage: mariadb_sec.exp \[mysql root password\]\n"
exit 1
}
set PASSWORD [lindex $argv 0];
spawn mysql_secure_installation
set mysql_spawn_id $spawn_id
# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/[exec whoami]/mariadb_install.log"
# when there is no password set, this probably should be "\r"
expect -ex "Enter current password for root (enter for none): "
exp_send "$PASSWORD\r"
expect {
# await an eventual error message
-ex "ERROR 1045" {
send_user "\nMariaDB > An invalid root password had been provided.\n"
close $mysql_spawn_id
exit 1
}
# when there is a root password set
-ex "Change the root password? \[Y/n\] " {
exp_send "n\r"
}
# when there is no root password set (could not test this branch).
-ex "Set root password? \[Y/n\] " {
exp_send "Y\r"
expect -ex "New password: "
exp_send "$PASSWORD\r"
expect -ex "Re-enter new password: "
exp_send "$PASSWORD\r"
}
}
expect -ex "Remove anonymous users? \[Y/n\] "
exp_send "Y\r"
expect -ex "Disallow root login remotely? \[Y/n\] "
exp_send "Y\r"
expect -ex "Remove test database and access to it? \[Y/n\] "
exp_send "Y\r"
expect -ex "Reload privilege tables now? \[Y/n\] "
exp_send "Y\r"
expect eof
close $mysql_spawn_id
exit 0
Для целей отладки - или для проверки ответа можно запустить expect с лог-уровнем strace 4. Вероятно, это настолько авторитетно, насколько это возможно для источника, когда речь идет о написании expect сценариев, так как оно прекрасно отображает происходящее и, что наиболее важно, в каком порядке все происходит:
expect -c "strace 4" ./mariadb_yum.exp [linux sudo password]
expect -c "strace 4" ./mariadb_sec.exp [mysql root password]
Инструкция set exp_internal 1 может использоваться для получения выходных данных для сопоставления регулярному выражению.
Возможным источником путаницы может быть тот, когда кто-то порождает процессы - так как он может порождать несколько процессов на разных хостах, например. ssh локально, а затем yum и mysql_secure_installation удаленно. Добавлен $spawn_id в скрипт; нижний close вызов может быть избыточным, поскольку он уже EOF (просто чтобы показать, как spawn и close процессы):
Thanks for using MariaDB!
1 close $mysql_spawn_id
1 exit 0
2 rename _close.pre_expect close
Вывод: * Сценарий 1042 *, вероятно, может быть улучшен, например. если сначала не отправлять пароль и видеть, что происходит, то отправлять пароль по ERROR 1045 (если пароль уже был установлен ранее). Можно предположить, что необходимо установить пароль, когда сервер только что был установлен (за исключением того, что yum reinstall дает тот же результат). Просто не было пустого контейнера CentOS для тестирования всех случаев. Если не запускать в оболочке root, передача обоих типов паролей в один сценарий потребует автоматизации этого процесса от установки до установки.
Вероятно, стоит отметить, что на GCE sudo не будет запрашивать для пароля; действительно, существуют незначительные различия в зависимости от среды, поскольку эти изображения контейнеров CentOS ведут себя по-разному. В этом случае (поскольку su или обнаружение контейнерного изображения не установлено), сценарий mariadb_yum.exp может зависнуть на 30 секунд и затем продолжить.
Наиболее авторитетные источники Я могу предложить руководство expect, написанное Доном Либесом @ NIST, и руководство TCL / TK для expect вместе с проектом SourceForge, который по совпадению называется expect.