XSLT: работа с основными элементами TEI - PullRequest
Новая
       42

XSLT: работа с основными элементами TEI

0 голосов
/ 06 февраля 2020

Мой вопрос связан с: XSLT с перекрывающимися элементами? - но предложенное решение не работает для меня.

Ввод

У меня есть TEI- XML, закодированный так: 

<delSpan spanTo="#abcbb6b8-b7bd-4b96-93c1-0a34500e12c0"/>
<lg>
    <l>some text that is deleted</l>
</lg>
<lg>
    <l>much more text</l>
    <l>another line of text</l>
</lg>
<anchor xml:id="abcbb6b8-b7bd-4b96-93c1-0a34500e12c0"/>

Я хочу обработать его с помощью XSL и мой вывод должен выглядеть так: 

<div class="delSpan">
    <div class="lg">
        <span>some text that is deleted</span>
    </div>
    <div class="lg">
        <span>much more text</span>
        <span>another line of text</span>
    </div>
</div>

XSLT В данный момент я пытаюсь работать со следующими шаблонами: 

<xsl:template match="tei:delSpan">
    <xsl:variable name="id">
        <xsl:value-of select="substring-after(@spanTo, '#')"/>
    </xsl:variable>
    <xsl:for-each-group select="*" group-ending-with="tei:anchor[@xml:id=$id]">
        <div class="delSpan">
            <xsl:apply-templates />
        </div>
    </xsl:for-each-group>
</xsl:template>

<xsl:template match="tei:lg">
    <div class="lg">
        <xsl:apply-templates/>
    </div>
</xsl:template>

<xsl:template match="tei:l">
    <span>
        <xsl:apply-templates/>
    </span>
</xsl:template>

Но это просто приводит к следующему выводу: 

<div class="lg">
        <span>some text that is deleted</span>
    </div>
    <div class="lg">
        <span>much more text</span>
        <span>another line of text</span>
    </div>

Поэтому я спрашиваю себя, есть ли какое-нибудь общее и простое решение для работы с так называемыми веховыми элементами и процессами, как описано выше?

1 Ответ

1 голос
/ 06 февраля 2020

Если вы переместите for-each-group к родительскому элементу любого delSpan (или любого элемента, к которому вы собираетесь применить перенос), он будет выглядеть как 

  <xsl:template match="*[delSpan]">
      <xsl:for-each-group select="*" group-starting-with="delSpan">
          <xsl:choose>
              <xsl:when test="self::delSpan">
                  <xsl:variable name="id-ref" select="substring(@spanTo, 2)"/>
                  <div class="{local-name()}">
                      <xsl:for-each-group select="current-group() except ." group-ending-with="id($id-ref)">
                          <xsl:choose>
                              <xsl:when test="current-group()[last()] is id($id-ref)">
                                  <xsl:apply-templates select="current-group()[not(position() = last())]"/>
                              </xsl:when>
                              <xsl:otherwise>
                                  <xsl:apply-templates select="current-group()"/>
                              </xsl:otherwise>
                          </xsl:choose>
                      </xsl:for-each-group>
                  </div>
              </xsl:when>
              <xsl:otherwise>
                  <xsl:apply-templates select="current-group()"/>
              </xsl:otherwise>
          </xsl:choose>
      </xsl:for-each-group>
  </xsl:template>

https://xsltfiddle.liberty-development.net/pPJ9hEk/1

...