Terraform - Несколько триггеров aws_s3_bucket_notification в одном ведре - PullRequest
Новая
       9

Terraform - Несколько триггеров aws_s3_bucket_notification в одном ведре

1 голос
/ 03 марта 2020

Мне нужно создать триггер для корзины S3. Мы используем следующее для создания триггера: 

resource "aws_s3_bucket_notification" "bucket_notification" {
  bucket = var.aws_s3_bucket_id

  lambda_function {
    lambda_function_arn = var.lambda_function_arn
    events              = ["s3:ObjectCreated:Put"]
    filter_prefix       = var.filter_prefix
    filter_suffix       = var.filter_suffix
  }
}

Это прекрасно работает, когда в корзине еще нет триггера, который имел место для всех сред, кроме рабочей. Когда мы развернули производство, мы увидели, что триггер, который уже присутствовал в корзине, был удален. Нам нужны оба триггера. Мне удалось добавить другой триггер вручную, например триггер события PUT, просто изменив префикс, однако, когда я делаю это из Terraform, предыдущий всегда удаляется. Я что-то пропустил?

1 Ответ

1 голос
/ 03 марта 2020

В документации по ресурсам aws_s3_bucket_notification это упоминается сверху:

ПРИМЕЧАНИЕ: S3 Buckets поддерживает только одну конфигурацию уведомлений. Объявление нескольких ресурсов aws_s3_bucket_notification для одного и того же S3 Bucket приведет к постоянной разнице в конфигурации. См. Пример «Запуск нескольких лямбда-функций».

В их примере показано, как это можно сделать, добавив несколько блоков lambda_function в ресурс aws_s3_bucket_notification: 

resource "aws_iam_role" "iam_for_lambda" {
  name = "iam_for_lambda"

  assume_role_policy = <<EOF
{
  "Version": "2012-10-17",
  "Statement": [
    {
      "Action": "sts:AssumeRole",
      "Principal": {
        "Service": "lambda.amazonaws.com"
      },
      "Effect": "Allow"
    }
  ]
}
EOF
}

resource "aws_lambda_permission" "allow_bucket1" {
  statement_id  = "AllowExecutionFromS3Bucket1"
  action        = "lambda:InvokeFunction"
  function_name = "${aws_lambda_function.func1.arn}"
  principal     = "s3.amazonaws.com"
  source_arn    = "${aws_s3_bucket.bucket.arn}"
}

resource "aws_lambda_function" "func1" {
  filename      = "your-function1.zip"
  function_name = "example_lambda_name1"
  role          = "${aws_iam_role.iam_for_lambda.arn}"
  handler       = "exports.example"
  runtime       = "go1.x"
}

resource "aws_lambda_permission" "allow_bucket2" {
  statement_id  = "AllowExecutionFromS3Bucket2"
  action        = "lambda:InvokeFunction"
  function_name = "${aws_lambda_function.func2.arn}"
  principal     = "s3.amazonaws.com"
  source_arn    = "${aws_s3_bucket.bucket.arn}"
}

resource "aws_lambda_function" "func2" {
  filename      = "your-function2.zip"
  function_name = "example_lambda_name2"
  role          = "${aws_iam_role.iam_for_lambda.arn}"
  handler       = "exports.example"
}

resource "aws_s3_bucket" "bucket" {
  bucket = "your_bucket_name"
}

resource "aws_s3_bucket_notification" "bucket_notification" {
  bucket = "${aws_s3_bucket.bucket.id}"

  lambda_function {
    lambda_function_arn = "${aws_lambda_function.func1.arn}"
    events              = ["s3:ObjectCreated:*"]
    filter_prefix       = "AWSLogs/"
    filter_suffix       = ".log"
  }

  lambda_function {
    lambda_function_arn = "${aws_lambda_function.func2.arn}"
    events              = ["s3:ObjectCreated:*"]
    filter_prefix       = "OtherLogs/"
    filter_suffix       = ".log"
  }
}
...