AttributeError: у объекта 'MuParser' нет атрибута 'startRule' - PullRequest
Новая
       60

AttributeError: у объекта 'MuParser' нет атрибута 'startRule'

1 голос
/ 11 февраля 2020

Итак, я скопировал этот код из ТА ответа : 

grammar Mu;

parse
 : block EOF
 ;

block
 : stat*
 ;

stat
 : assignment
 | if_stat
 | while_stat
 | log
 | OTHER {System.err.println("unknown char: " + $OTHER.text);}
 ;

assignment
 : ID ASSIGN expr SCOL
 ;

if_stat
 : IF condition_block (ELSE IF condition_block)* (ELSE stat_block)?
 ;

condition_block
 : expr stat_block
 ;

stat_block
 : OBRACE block CBRACE
 | stat
 ;

while_stat
 : WHILE expr stat_block
 ;

log
 : LOG expr SCOL
 ;

expr
 : expr POW<assoc=right> expr           #powExpr
 | MINUS expr                           #unaryMinusExpr
 | NOT expr                             #notExpr
 | expr op=(MULT | DIV | MOD) expr      #multiplicationExpr
 | expr op=(PLUS | MINUS) expr          #additiveExpr
 | expr op=(LTEQ | GTEQ | LT | GT) expr #relationalExpr
 | expr op=(EQ | NEQ) expr              #equalityExpr
 | expr AND expr                        #andExpr
 | expr OR expr                         #orExpr
 | atom                                 #atomExpr
 ;

atom
 : OPAR expr CPAR #parExpr
 | (INT | FLOAT)  #numberAtom
 | (TRUE | FALSE) #booleanAtom
 | ID             #idAtom
 | STRING         #stringAtom
 | NIL            #nilAtom
 ;

OR : '||';
AND : '&&';
EQ : '==';
NEQ : '!=';
GT : '>';
LT : '<';
GTEQ : '>=';
LTEQ : '<=';
PLUS : '+';
MINUS : '-';
MULT : '*';
DIV : '/';
MOD : '%';
POW : '^';
NOT : '!';

SCOL : ';';
ASSIGN : '=';
OPAR : '(';
CPAR : ')';
OBRACE : '{';
CBRACE : '}';

TRUE : 'true';
FALSE : 'false';
NIL : 'nil';
IF : 'if';
ELSE : 'else';
WHILE : 'while';
LOG : 'log';

ID
 : [a-zA-Z_] [a-zA-Z_0-9]*
 ;

INT
 : [0-9]+
 ;

FLOAT
 : [0-9]+ '.' [0-9]*
 | '.' [0-9]+
 ;

STRING
 : '"' (~["\r\n] | '""')* '"'
 ;

COMMENT
 : '#' ~[\r\n]* -> skip
 ;

SPACE
 : [ \t\r\n] -> skip
 ;

OTHER
 : .
 ;

Я скомпилировал код в python, выполнив: antlr4 -Dlanguage=Python3 Mu.g4

И затем Я попытался запустить сценарий python, используя сгенерированные классы python: 

import sys
from antlr4 import *
from MuLexer import MuLexer
from MuParser import MuParser

def main(argv):
    input_stream = FileStream(argv[1])
    lexer = MuLexer(input_stream)
    stream = CommonTokenStream(lexer)
    parser = MuParser(stream)
    tree = parser.startRule()

if __name__ == '__main__':
    main(sys.argv)

Я назвал этот сценарий так: python3 script.py test.txt

Вывод, однако: AttributeError: 'MuParser' object has no attribute 'startRule'

Я не понимаю, почему это происходит, весь код, который я имею, скопирован из учебников.

1 Ответ

2 голосов
/ 11 февраля 2020

Как уже упоминалось в комментариях, startRule следует заменить на parse в вашем случае. Этот метод соответствует следующему правилу синтаксического анализа в грамматике: 

parse
 : block EOF
 ;

Каждое правило в грамматике переводится в метод / функцию, которую вы можете вызвать. Обычно вы хотите использовать правило с маркером EOF (конец файла) в конце: таким образом вы заставляете синтаксический анализатор потреблять все токены из входного потока.

И печатать строковое представление вашего дерева разбора, добавьте это: 

print(tree.toStringTree(recog=parser))
...