xslt объединяет атрибуты в разных группах - PullRequest
Новая
       2

xslt объединяет атрибуты в разных группах

1 голос
/ 16 января 2020

Я использую xslt 1.0. Пожалуйста, помогите мне, как написать xslt. У меня есть XML. 

<xml name="wwwqqq">
<group key="attribute">
    <attribute id="1" name="AA"/>
    <attribute id="2" name="BB"/>
    <attribute id="3" name="СС"/>
</group>
<group key="tie">
    <tie id="1"/>
    <tie id="2"/>
</group>
<group key="job">
    <job id="1" fromTieId="1" toAttributeId="1"  job="bbbbb"/>
    <job id="2" fromTieId="1" toAttributeId="2"  job="aaaaa"/>
    <job id="3" fromTieId="2" toAttributeId="2"  job="aaaaa"/>
    <job id="4" fromTieId="2" toAttributeId="3"  job="ссссс"/>
</group>

Я написал XSLT. 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="html" />
<xsl:key name="k_job" match="attribute" use="@id" />
<xsl:template match="/">
    <xsl:for-each select="xml/group[@key='job']/job">
        <xsl:apply-templates select="key('k_job', @toAttributeId)/@name" />
        <xsl:text>_</xsl:text>
        <xsl:value-of select="@job"/>
        <xsl:text> @fromTieId=</xsl:text>
        <xsl:value-of select="@fromTieId"/>
        <br />
    </xsl:for-each>
</xsl:template>

Мне нужно это вместо вывода

AA_bbbbb @ fromTieId = 1

BB_aaaaa @ fromTieId = 1

BB_aaaaa @ fromTieId = 2

СС_ссссс @ fromTieId = 2

получить * 10 10 * получить * 10 10

AA_bbbbb_ BB_aaaaa

BB_aaaaa_ СС_ссссс

1 Ответ

0 голосов
/ 16 января 2020

Итак, вы хотите сгруппировать элементы job сначала по атрибуту fromTieId? Для этого используйте мюнхенскую группировку с <xsl:key name="job-group" match="job" use="@fromTieId"/>, а затем 

<xsl:for-each select="xml/group[@key='job']/job[generate-id() = generate-id(key('job-group', @fromTieId)[1])]">
        <xsl:apply-templates select="key('k_job', key('job-group', @fromTieId)/@toAttributeId)/@name" />

. Для полного рефакторинга с использованием шаблонов (но с теми же ключами для группировки / ссылки), я думаю, поможет следующий подход: 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:strip-space elements="*"/>

<xsl:output method="html" indent="yes" version="5.0" doctype-system="about:legacy-doctype" />

<xsl:key name="k_job" match="attribute" use="@id" />

<xsl:key name="job-group" match="job" use="@fromTieId"/>

<xsl:template match="/">
    <html>
        <head>
            <title>Example</title>
        </head>
        <body>
            <xsl:apply-templates/>
        </body>
    </html>
</xsl:template>

<xsl:template match="xml/group[@key='job']/job[generate-id() = generate-id(key('job-group', @fromTieId)[1])]">
        <xsl:apply-templates select="key('job-group', @fromTieId)" mode="value"/>
        <xsl:text> @fromTieId=</xsl:text>
        <xsl:value-of select="@fromTieId"/>
        <br />    
</xsl:template>

<xsl:template match="xml/group[@key='job']/job[generate-id() != generate-id(key('job-group', @fromTieId)[1])]"/>

<xsl:template match="job" mode="value">
        <xsl:apply-templates select="key('k_job', @toAttributeId)/@name" />
        <xsl:text>_</xsl:text>
        <xsl:value-of select="@job"/>    
</xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/3NSTbeJ

Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...