Таблица Google Data Studio: деление данных на 2 года - PullRequest
Новая
       4

Таблица Google Data Studio: деление данных на 2 года

1 голос
/ 04 марта 2020

Мне нужно создать таблицу с котировками win%. Формула #won делить на #sent. Моя проблема в том, что есть цитаты, которые были выиграны в течение года, но были отправлены в разные годы.

(Мои данные получены из BigQuery)

Данные выглядят так: 

Sale    Sent    Won
sale1   2019    2020
sale2   2019    2020
sale3   2016    2017
sale4   2017    2019
sale5   2020    2020
sale6   2020    2020
sale7   2018    2018
sale8   2016    2016
sale9   2015    2016
sale10  2016    2017
sale11  2016    2018
sale12  2018    2019

Я хотел бы иметь возможность создать таблицу в студии данных, как это : 

Year   SENT    WON  WIN%
2016     4     2    50%
2017     1     2    200%
2018     2     2    100%
2019     2     2    100%
2020     2     4    200%

Я хотел бы посмотреть, возможно ли это в Google Data Studio. Любое предложение высоко ценится.

1 Ответ

0 голосов
/ 04 марта 2020

Добавлен Отчет Google Data Studio для демонстрации, а также GIF, показывающий процесс, приведенный ниже.

Один из подходов заключается в реструктуризации данных в наборе данных * 1006. * и используйте Расчетные поля в Таблице :

1) Преобразование данных
Данные должны быть преобразованы из текущего Широкая структура в Длинная структура данных . Одним из способов достижения этого в Google Sheets является использование приведенной ниже формулы (Sheet1 представляет исходный лист; обратитесь за разъяснениями к встроенному Google Sheet): 

=ArrayFormula(QUERY({
{Sheet1!A:A,IF(LEN(Sheet1!A:A),"Sent",""),Sheet1!B:B};
{Sheet1!A:A,IF(LEN(Sheet1!A:A),"Won",""),Sheet1!C:C}
},"Select * Where Col3 is not null Label Col2 'Dimension', Col3 'Year'",1))

2) Таблица
- Размер : Year
- Сортировка : Year в порядке возрастания
- Метрики : Добавьте 3 вычисляемых поля ниже:

3) Вычисляемые поля
Приведенные ниже формулы создают метрики, используемые в приведенной выше таблице (Формула 3.1 и 3.2 должна быть добавлена ​​на уровне источника данных , тогда как 3.3 может быть добавлена ​​на уровне диаграммы , если требуется):

3.1) Отправлено 

COUNT(CASE
   WHEN REGEXP_MATCH(Dimension, "Sent") THEN Year
   ELSE NULL END)

3.2) WON 

COUNT(CASE
   WHEN REGEXP_MATCH(Dimension, "Won") THEN Year
   ELSE NULL END)

3.3) WIN% 

WON / SENT

5]

...