Запуск WebServerSecure и PubSubClient на ESP8266

Question

Я написал эскиз для ESP8266. Этот эскиз считывает некоторые данные датчика и публикует их через MQTT. Кроме того, я хочу, чтобы веб-сервер предоставлял те же данные, что и веб-служба HTML или JSON.

MQTT publi sh запускается с помощью таймера TaskScheduler.

Обе функции, MQTT и веб-сервер, работают для себя, но, к сожалению, не вместе. Вот упрощенный набросок:

#include <ESP8266WiFi.h>
#include <ESP8266mDNS.h>
#include <ESP8266WebServerSecure.h>
#include <PubSubClient.h>
#include <TaskScheduler.h>

#include <My_WLAN.h>                          // provices connection to local WLAN and network settings

const char DNS_NAME[] = "myserver.local";
const int  HTTPS_PORT = 443;                  // HTTPS
const char MQTT_SVR[] = "myserver.local";
const unsigned int MQTT_PORT = 8883;          // MQTTS

WiFiClientSecure  wifiClient;
PubSubClient      mqttClient(wifiClient);     // MQTT client instance
ESP8266WebServerSecure  server(HTTPS_PORT);   // web server instance

void t1Callback(void);                        // callback method prototypes
Task              t1(60000, TASK_FOREVER, &t1Callback);   // main loop task
Scheduler         timer;                      // task scheduler

static const uint8_t SVR_FINGERPRINT[20] PROGMEM = { 0x01, 0x02, 0x03, 0x04, 0x05, 0x06, 0x07, 0x08, 0x09, 0x10, 0x11, 0x12, 0x13, 0x14, 0x15, 0x16, 0x17, 0x18, 0x19, 0x20 };

static const char deviceCert[] PROGMEM = R"EOF(
-----BEGIN CERTIFICATE-----
[... certificate ...]
-----END CERTIFICATE-----
)EOF";

static const char deviceKey[] PROGMEM = R"EOF(
-----BEGIN RSA PRIVATE KEY-----
[... key ...]
-----END RSA PRIVATE KEY-----
)EOF";


/* *****************************
      MQTT_connect
 * *****************************/
void MQTT_connect()
{
  int attempt = 0;
  /* loop until reconnected */
  while (!mqttClient.connected() && attempt < 10) {
    attempt++;
    Serial.print("Attempting MQTT connection ("); Serial.print(attempt); Serial.print(")...");

    mqttClient.setServer(MQTT_SVR, MQTT_PORT);

    if (mqttClient.connect(DNS_NAME)) {
      Serial.println("success");

    } else {
      Serial.print("failed, status code = "); Serial.print(mqttClient.state());
      Serial.println(". - Try again in 5 seconds...");
      delay(5000);
    }
  }
}


/* *****************************
      Web Server handleRoot
 * *****************************/
void handleRoot() {
  digitalWrite(LED_BUILTIN, LOW); // on

  Serial.println("WebServer ROOT");
  server.send(200, "text/html", "WebServer ROOT");

  digitalWrite(LED_BUILTIN, HIGH); // off
}

/* *****************************
      Web Server handleNotFound
 * *****************************/
void handleNotFound() {
  digitalWrite(LED_BUILTIN, LOW); // on

  String message = "File not found\n\n";
  message += "URI: ";
  message += server.uri();
  message += "\nMethod: ";
  message += (server.method() == HTTP_GET) ? "GET" : "POST";
  message += "\nArguments: ";
  message += server.args();
  message += "\n";

  for (uint8_t i = 0; i < server.args(); i++) {
    message += " " + server.argName(i) + ": " + server.arg(i) + "\n";
  }

  server.send(404, "text/plain", message);

  digitalWrite(LED_BUILTIN, HIGH); // off
}


/* *************************
      MQTT_publish_something
 * *************************/
void MQTT_publish_something() {
  digitalWrite(LED_BUILTIN, LOW); // on

  char payload[30] = "some_payload_data";

  if (!mqttClient.publish("MQTT/Test", payload, true)) {  // retain message
    Serial.println("MQTT message lost!");
  }

  digitalWrite(LED_BUILTIN, HIGH); // off
}


/* *************************
   t1: main timer (callback)
 * *************************/
void t1Callback() {
  my.WiFi_connect();    // check and re-connect to WLAN (in My_WLAN.h)

  if (WiFi.status() == WL_CONNECTED) {
    MQTT_connect();

    MQTT_publish_something();
  }
}


/* *************************
      setup
 * *************************/
void setup() {
  pinMode(LED_BUILTIN, OUTPUT);     // internal LED
  digitalWrite(LED_BUILTIN, HIGH);  // off

  /* -----------------------
        open Serial        |
     ----------------------- */
  Serial.begin(74880);
  while (!Serial);   // wait for Serial being ready

  /* -----------------------
        connect to WLAN    |
     ----------------------- */
  my.WiFi_connect();  // this is connecting to WLAN & error handling (in My_WLAN.h)
  wifiClient.setFingerprint(SVR_FINGERPRINT);

  /* -----------------------
        set mDNS           |
     ----------------------- */
  if (MDNS.begin(DNS_NAME)) {
    Serial.printf("mDNS responder started for %s\n", DNS_NAME);
    MDNS.addService("https", "tcp", HTTPS_PORT);   // add service to MDNS-SD
    MDNS.addService("mqtt",  "tcp", MQTT_PORT);
  } else
    Serial.println("Error setting up mDNS responder!");

  /* -----------------------
        start HTTPS server |
     ----------------------- */
  server.getServer().setRSACert(new X509List(deviceCert), new PrivateKey(deviceKey));

  server.on("/", handleRoot);                 // standard HTML root
  server.onNotFound(handleNotFound);
  server.begin();

  Serial.println("HTTPS server started.");
  Serial.println();


  /* -----------------------
        start timer        |
     ----------------------- */
  timer.init();
  timer.addTask(t1);
  // line 177:
  timer.enableAll();
}

void loop() {
  MDNS.update();

  // line 184:
  server.handleClient();

  mqttClient.loop();

  timer.execute();
}

Запуск MQTT работает только отлично и публикует данные (я использую брокер Mosquitto). Запуск веб-сервера (https://...) Также работает нормально, если закомментировать строку 177 (поэтому MQTT не запускается).

Когда обе функции активны, как только первое сообщение MQTT было отправлено, веб-сервер больше не отвечает. Я получаю PR_END_OF_FILE_ERROR в FF и ERR_CONNECTION_CLOSED в Chrome.

Я предполагаю, что эти библиотеки каким-то образом связываются друг с другом или что-то путает с сертификатами. Однако отпечаток пальца принадлежит серверу, на котором запущен mosquitto, а сертификат X509 принадлежит веб-серверу, работающему на ESP8266. Это две разные машины и не имеют ничего общего друг с другом.

Любая идея приветствуется.