Можно ли создать YAML из _within_ выражения dhall? - PullRequest
Новая
       11

Можно ли создать YAML из _within_ выражения dhall?

1 голос
/ 21 апреля 2020

Я хотел бы создать ConfigMap для службы, использующей dhall-kubernetes. Служба настроена с использованием файла YAML. Я могу использовать dhall для создания конфигурации в два этапа: 

$ dhall-to-yaml < server.dhall > server.yaml
$ dhall-to-yaml < configmap.dhall 
apiVersion: v1
data:
  server.yaml: |
    server:
      port: 8080
kind: ConfigMap
metadata:
  name: my-configmap

server.dhall: 

let _config = { server.port = 8080 } in _config

configmap.dhall: 

let kubernetes =
      ./package.dhall sha256:d9eac5668d5ed9cb3364c0a39721d4694e4247dad16d8a82827e4619ee1d6188

let _configMap1 =
      kubernetes.ConfigMap::{
      , metadata = kubernetes.ObjectMeta::{ name = "my-configmap" }
      , data = Some
        [ { mapKey = "server.yaml", mapValue = ./server.yaml as Text } ]
      }

in  _configMap1

package.dhall 

https://raw.githubusercontent.com/dhall-lang/dhall-kubernetes/master/package.dhall

Можно ли использовать только один вызов dhall-to-yaml, генерируя YAML из dhall? Примерно так: 

let kubernetes =
      ./package.dhall sha256:d9eac5668d5ed9cb3364c0a39721d4694e4247dad16d8a82827e4619ee1d6188

let _config = { server.port = 8080 }

let _configMap3 =
      kubernetes.ConfigMap::{
      , metadata = kubernetes.ObjectMeta::{ name = "my-configmap" }
      , data = Some
        [ { mapKey = "server.yaml"
          , mapValue = makeYAML _config -- make this work 
          }   
        ]   
      }   

in  _configMap3

Я нашел функцию JSON .renderYAML в Prelude, но, похоже, это не совсем то, что нужно.

1 Ответ

1 голос
/ 21 апреля 2020

Чтобы сгенерировать YAML с использованием Prelude.JSON.renderYAML, сначала необходимо преобразовать конфигурацию в тип ввода Prelude.JSON.Type. См. Функцию makeJSON, включенную в мою версию makeYAML ниже: 

let Prelude = https://prelude.dhall-lang.org/v15.0.0/package.dhall

let J = Prelude.JSON

let Config = { server : { port : Natural } }

let makeJSON
    : Config → J.Type
    =   λ(c : Config)
      → J.object
          ( toMap
              { server = J.object (toMap { port = J.natural c.server.port }) }
          )

let makeYAML
    : Config → Text
    = λ(c : Config) → J.renderYAML (makeJSON c)

let example =
      let _config
          : Config
          = { server.port = 8080 }

      in    assert
          :   makeYAML _config
            ≡ ''
              "server":
                "port": 8080
              ''

in  makeYAML
...