Копировать / Вставить в DataGridView - PullRequest
Новая
       23

Копировать / Вставить в DataGridView

1 голос
/ 21 апреля 2020

Я пытаюсь сделать копию и вставить в DataGridView, чтобы действовать аналогично Excel. Мой текущий код выполняет это за исключением первой ячейки, которая, кажется, вставляет все содержимое из буфера обмена в первую ячейку. Ниже приведен код, который я использую для события cell_keydown.

Просто чтобы уточнить, если я скопирую следующее:

Copied Data

Я получу результат:

Pasted Data

Вставленные данные имеют пробел между двумя датами до нажатия на ячейку.

Если у кого-то есть лучший способ выполнить sh, то, что я в конечном итоге пытаюсь сделать, будет также оценено! 

If e.Control AndAlso e.KeyCode = Keys.C Then
    Dim d As DataObject = dgv1.GetClipboardContent()
    Clipboard.SetDataObject(d)
    e.Handled = True

ElseIf e.Control AndAlso e.KeyCode = Keys.V Then
    Dim s As String = Clipboard.GetText().Replace(vbCr, " ")
    Dim lines As String() = s.Trim.Split(vbLf)
    Dim row As Integer = dgv1.CurrentCell.RowIndex
    Dim col As Integer = dgv1.CurrentCell.ColumnIndex
    Dim linesCount As Integer = lines.Count()

    If (row + linesCount) - dgv1.RowCount > 0 Then dgv1.Rows.Add((row + linesCount) - dgv1.RowCount)

    For Each line As String In lines
        If line.Length > 0 Then
            Dim cells As String() = line.Split(vbTab)
            For i As Integer = 0 To cells.GetLength(0) - 1
                dgv1.CurrentCell.Value = cells(i)
                If col + i < dgv1.ColumnCount Then
                    dgv1(col + i, row).Value = cells(i)
                Else
                    Exit For
                End If
            Next
            row += 1
        Else
            Exit For
        End If
    Next
End If

1 Ответ

0 голосов
/ 21 апреля 2020

Лучше создавать методы для процедур копирования / вставки, чтобы вы могли вызывать их из разных мест в вашем коде, например, при нажатии кнопки, при нажатии клавиши, при нажатии пункта меню ... et c.

Я не думаю, что у вас есть проблема с частью Copy, так как функция GetClipboardContent выполнит эту работу. Что касается части Paste, следующий фрагмент кода получает данные из буфера обмена и вставляет значения диапазона выбора ячеек, начиная с CurrentCell. Ячейки вне диапазона обрезаются. 

Private Sub CopyCells()
    Clipboard.SetDataObject(DataGridView1.GetClipboardContent)
End Sub

Private Sub PasteCells()
    Dim s = Clipboard.GetText
    Dim ci = DataGridView1.CurrentCell.ColumnIndex
    Dim ri = DataGridView1.CurrentCell.RowIndex
    Dim colCount = DataGridView1.Columns.Count
    Dim rowCount = DataGridView1.Rows.Count

    For Each r In s.Split({ControlChars.CrLf}, StringSplitOptions.None)
        Dim Cell = ci
        For Each c In r.Split({ControlChars.Tab}, StringSplitOptions.None)
            If Cell >= colCount Then Exit For
            DataGridView1(Cell, ri).Value = c
            Cell += 1
        Next
        ri += 1
        If ri >= rowCount Then Exit For
    Next
End Sub

Вызовите их из события DGV.KeyDown, например, следующим образом: 

Private Sub DataGridView1_KeyDown(sender As Object, e As KeyEventArgs) Handles DataGridView1.KeyDown
    If e.Control Then
        Select Case e.KeyCode
            Case Keys.C
                CopyCells()
                e.Handled = True
            Case Keys.V
                PasteCells()
                e.Handled = True
        End Select
    End If
End Sub
...