XSLT: передать имя элемента в виде строки и преобразовать его в выражение XPATH - PullRequest
Новая
       24

XSLT: передать имя элемента в виде строки и преобразовать его в выражение XPATH

0 голосов
/ 06 марта 2020

Возможно ли с XSLT 3.0 до преобразовать строку в имя элемента в XPATH-запросе ? Я хотел бы передать имя элемента в виде строки в шаблон, а затем включить имя элемента в XPATH-выражение. Примерно так <xsl:variable name="el-name" select="'p'"/><xsl:copy-of select="$el-name"/>, где el-name больше не является строкой, но выбирает элемент p. Предположим, у меня есть исходный документ, подобный этому: 

<?xml version="1.0" encoding="UTF-8"?>
<text xmlns="">
    <list xml:id="p-1">
        <item n="1"/>
        <item n="2"/>
    </list>
    <head>This is a heading</head>
    <p xml:id="p-1">Lorem ipsum</p>
    <p xml:id="p-2">dolorosum</p>
</text>

И таблица стилей, подобная этой: 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="3.0" xmlns:xs="http://www.w3.org/2001/XMLSchema" xpath-default-namespace="" exclude-result-prefixes="xs" xmlns="">
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="/text">
        <selection-of-text xmlns="">
            <xsl:call-template name="get-elements">
                <xsl:with-param name="element-name" as="xs:string" select="'list'"/>
            </xsl:call-template>
            <xsl:call-template name="get-elements">
                <xsl:with-param name="element-name" as="xs:string" select="'p'"/>
            </xsl:call-template>
        </selection-of-text>
    </xsl:template>

    <xsl:template name="get-elements">
        <xsl:param name="element-name"/>
        <xsl:choose>
            <xsl:when test="$element-name = 'list'">
                <xsl:copy-of select="list"/>
            </xsl:when>
            <xsl:when test="$element-name = 'p'">
                <xsl:copy-of select="p"/>
            </xsl:when>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

В BASH Я запускаю 

java -cp "/mnt/c/Tools/SaxonHE9-9-1-4J/saxon9he.jar" net.sf.saxon.Transform \
-s:source.xml -xsl:stylesheet.xslt -o:output.xml

и получить желаемый результат: 

<?xml version="1.0" encoding="UTF-8"?>
<selection-of-text>
    <list xml:id="p-1">
        <item n="1"/>
        <item n="2"/>
    </list>
    <p xml:id="p-1">Lorem ipsum</p>
    <p xml:id="p-2">dolorosum</p>
</selection-of-text>

Мой код работает, но он неуклюжий. Я предполагаю, что xsl:evaluate может работать для динамического построения правильного выражения XPATH, но я не понимаю, как. https://www.w3.org/TR/xslt-30/#evaluate -эффект

1 Ответ

0 голосов
/ 06 марта 2020

Как любезно объяснил Мартин Хоннен выше, простое и короткое решение таково: 

<xsl:template name="get-elements">
    <xsl:param name="element-name"/>
    <xsl:copy-of select="*[name() = $element-name]"/>
</xsl:template>

Альтернативное решение, которое я тестировал с Saxon PE 9.9.1.4, это: 

<xsl:template name="get-elements">
    <xsl:param name="element-name"/>
    <xsl:variable name = "els">
        <xsl:evaluate xpath="$element-name" context-item="."/>
    </xsl:variable>
    <xsl:copy-of select="$els"/>
</xsl:template>
...