XSLT 2 | Альтернатива для каждого | При использовании do c ()

Question

Я пытался преобразовать:

... следующее: [CSKS doc]

<ZRFC_READ_TABLE.Response>
    <DATA>
        <item>
            <WA>20200306~99999999~123456~EUR  ~6000~1234~HELO      ~ ~</WA>
        </item>
        <item>
            <WA>20200306~99999999~789012~EUR  ~6000~1234~HEYL      ~ ~</WA>
        </item>
        <item>
            <WA>20200306~99999999~345678~EUR  ~6000~1234~HIYA      ~ ~</WA>
        </item>
    </DATA>
</ZRFC_READ_TABLE.Response>

со следующим источником поиска: [CSKT doc]

<ZRFC_READ_TABLE.Response>
    <DATA>
        <item>
            <WA>123456~This is a test message 1~</WA>
        </item>
        <item>
            <WA>789012~This is a test message 2~</WA>
        </item>
        <item>
            <WA>345678~This is a test message 3~</WA>
        </item>
    </DATA>
</ZRFC_READ_TABLE.Response>

с использованием следующего XSLT:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:param name="CSKT_FilePath"/>
    <xsl:param name="CSKS_FilePath"/>
    <xsl:template match="/">
        <xsl:element name="masterData">
            <xsl:choose>
                <xsl:when test="(not($CSKT_FilePath) and not(string($CSKT_FilePath))) and (not($CSKS_FilePath) and not(string($CSKS_FilePath)))">
                    <xsl:message terminate="yes">One or more Input Parameter(s) not supplied!</xsl:message>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:variable name="CSKTData" select="doc($CSKT_FilePath)"/>
                    <xsl:variable name="CSKSData" select="doc($CSKS_FilePath)"/>
                    <xsl:variable name="ReplaceFunction">
                        <ReplaceFunction name="LTEXT BY KOSTL">
                            <xsl:for-each select="$CSKTData/ZRFC_READ_TABLE.Response/DATA/item/WA">
                                <xsl:element name="item">
                                    <xsl:attribute name="key" select="replace(normalize-space(tokenize(., '~')[1]), '[^0-9a-zA-Z]+', '')"/>
                                    <!--<xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>-->
                                    <xsl:value-of select="normalize-space(tokenize(., '~')[2])"/>
                                    <!--<xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>-->
                                </xsl:element>
                            </xsl:for-each>
                        </ReplaceFunction>
                    </xsl:variable>             
                    <xsl:for-each select="$CSKSData/ZRFC_READ_TABLE.Response/DATA/item/WA">
                        <xsl:variable name="_ccDesc_In" select="replace(normalize-space(tokenize(., '~')[3]), '[^0-9a-zA-Z]+', '')"/>
                        <mdRec>
                            <dateFrom>
                                <xsl:value-of select="normalize-space(tokenize(., '~')[1])"/>
                            </dateFrom>
                            <dateTo>
                                <xsl:value-of select="normalize-space(tokenize(., '~')[2])"/>
                            </dateTo>
                            <costCenter>
                                <xsl:value-of select="normalize-space(tokenize(., '~')[3])"/>
                            </costCenter>
                            <cur>
                                <xsl:value-of select="normalize-space(tokenize(., '~')[4])"/>
                            </cur>
                            <contArea>
                                <xsl:value-of select="normalize-space(tokenize(., '~')[5])"/>
                            </contArea>
                            <compCode>
                                <xsl:value-of select="normalize-space(tokenize(., '~')[6])"/>
                            </compCode>
                            <profitCenter>
                                <xsl:value-of select="normalize-space(tokenize(., '~')[7])"/>
                            </profitCenter>
                            <lockInd>
                                <xsl:value-of select="normalize-space(tokenize(., '~')[8])"/>
                            </lockInd>
                            <ccDesc>
                                <xsl:value-of select="$ReplaceFunction//item[@key=$_ccDesc_In]/text()"/>
                            </ccDesc>
                        </mdRec>
                    </xsl:for-each>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

, который выдает требуемый результат, который выглядит следующим образом:

<masterData>
    <mdRec>
        <dateFrom>20200306</dateFrom>
        <dateTo>99999999</dateTo>
        <costCenter>123456</costCenter>
        <cur>EUR</cur>
        <contArea>6000</contArea>
        <compCode>1234</compCode>
        <profitCenter>HELO</profitCenter>
        <lockInd/>
        <ccDesc>This is a test message 1</ccDesc>
    </mdRec>
    <mdRec>
        <dateFrom>20200306</dateFrom>
        <dateTo>99999999</dateTo>
        <costCenter>789012</costCenter>
        <cur>EUR</cur>
        <contArea>6000</contArea>
        <compCode>1234</compCode>
        <profitCenter>HEYL</profitCenter>
        <lockInd/>
        <ccDesc>This is a test message 2</ccDesc>
    </mdRec>
    <mdRec>
        <dateFrom>20200306</dateFrom>
        <dateTo>99999999</dateTo>
        <costCenter>345678</costCenter>
        <cur>EUR</cur>
        <contArea>6000</contArea>
        <compCode>1234</compCode>
        <profitCenter>HIYA</profitCenter>
        <lockInd/>
        <ccDesc>This is a test message 3</ccDesc>
    </mdRec>
</masterData>

Это при работе с 1000 с [50000, должно быть точный] подсегмента WA в документе CSKS, преобразование занимает около 5-6 минут. Это может быть связано с использованием XSLT для каждого или с плохой сборкой. Есть ли лучшая альтернатива с точки зрения производительности?

Answer 1

Объявите ключ <xsl:key name="ltext-by-kostl" match="item" use="@key"/> как элемент верхнего уровня (т. Е. Дочерний элемент xsl:stylesheet или xsl:transform) в вашем XSLT, а затем вместо $ReplaceFunction//item[@key=$_ccDesc_In]/text() используйте key('ltext-by-kostl', $_ccDesc_In, $ReplaceFunction).

Это также может улучшить производительность, если вы не выполняете все эти tokenize вызовы, а вместо этого, где это возможно, используете функцию только один раз и сохраняете ее результат в переменной, например, <xsl:variable name="tokens" select="tokenize(...)"/>, а затем обращаетесь к $tokens[1], $tokens[2] там, где это необходимо .