Класси c Asp готовить ie срок годности не всегда устанавливается - PullRequest
Новая
       19

Класси c Asp готовить ie срок годности не всегда устанавливается

3 голосов
/ 13 февраля 2020

Я пытаюсь установить cook ie с помощью метода addheader в Classi c Asp, который является единственным способом добавления флагов HttpOnly и Secure -flags в файлы cookie. Все работают с приведенным ниже кодом - но есть одно исключение, и это дата и время истечения срока действия. 

<%
Response.AddHeader "Set-Cookie", "testCookie=2000; path=/;HttpOnly;Secure;expires=" & dateAdd("d", 365, Now()) & ";samesite=Strict;HostOnly"
%>

Однако, похоже, это проблема, связанная с браузером. В firefox я вижу на вкладке «Хранение» инструментов разработчика, что время истечения установлено. Но в Chrome он всегда остается значением по умолчанию, которое является истечением с окончанием сеанса. Эта же проблема и с Edge.

Кто-нибудь имел опыт решения этой проблемы?

Ответы [ 2 ]

4 голосов
/ 16 февраля 2020

Ожидаемый формат даты задокументирован здесь . Вы должны указать дату окончания срока действия таким образом.

В Classi c ASP вы можете использовать серверную JavaScript, чтобы легко создавать такие даты. 

<!--#include file="HTTPDate.asp"-->
<%
Response.AddHeader "Set-Cookie", "testCookie=2000; path=/;HttpOnly;Secure;expires=" & HTTPDate(DateAdd("d", 365, Now())) & ";samesite=Strict;HostOnly"
%>

HTTPDate . asp

<script language="javascript" runat="server">
function HTTPDate(vbsDate){
    return (new Date(vbsDate)).toGMTString().replace(/UTC/, "GMT");
}
</script>

Редактировать: Добавлено чистое решение VBScript. 

<%
Function CurrentTZO()
    With CreateObject("WScript.Shell") 
        CurrentTZO = .RegRead( _ 
        "HKLM\System\CurrentControlSet\Control\TimeZoneInformation\ActiveTimeBias")
    End With
End Function

Function Pad(text)
    Pad = Right("00" & text, 2)
End Function

Function HTTPDate(ByVal localDate)
    localDate = DateAdd("n", CurrentTZO(), localDate)

    ' WeekdayName and MonthName functions relies on locale
    ' need to produce day and month name abbreviations in en-US locale
    Dim locale : locale = SetLocale("en-US")

    Dim out(5)
    out(0) = WeekdayName(Weekday(localDate), True) & ","
    out(1) = Pad(Day(localDate))
    out(2) = MonthName(Month(localDate), True)
    out(3) = Year(localDate)
    out(4) = Join(Array(Pad(Hour(localDate)), Pad(Minute(localDate)), Pad(Second(localDate))), ":")
    out(5) = "GMT"

    SetLocale locale ' set original locale back 

    HTTPDate = Join(out, " ")
End Function

Response.AddHeader "Set-Cookie", "testCookie=2000; path=/;HttpOnly;Secure;expires=" & HTTPDate(DateAdd("d", 365, Now())) & ";samesite=Strict;HostOnly"
%>
0 голосов
/ 17 февраля 2020

В дополнение к общепринятому решению Кул-Тигина я хочу добавить также решение vbscript для тех, кто тоже этого не хватает. 

<%
Response.AddHeader "Set-Cookie", "testCookie=2000; path=/;HttpOnly;Secure;expires=" & (New UTC).toUTCString(500,"d") & ";samesite=Strict;HostOnly;"


Class UTC

    Public Function toUTCString(ByVal offSet, ByVal offsetType)
        ' ***********************************
        ' Converts vbScript datetime format to 
        ' Universal datetime string format:
        ' Tue, 16 Feb 2021 13:39:24 GMT
        '************************************

        Dim dt: dt = dateAdd(offsetType, offSet, UTCDate(Now()))
        Dim tdParts: tdParts = Split(dt, " ")
        Dim tPart: tPart = CDate(tdParts(1) & " " & tdParts(2))
        Dim dPart: dPart = CDate(tdParts(0))

        Dim timeTo24: timeTo24 = _
        Right("0" & Hour(tPart), 2) & ":" & _
        Right("0" & Minute(tPart), 2) & ":" & _
        Right("0" & Second(tPart), 2)

        toUTCString = WeekdayName(Weekday(dPart), True) & ", " & _
                      Day(dPart) & " " & _
                      MonthName(Month(dPart), True) & " " & _
                      Year(dPart) & " " & _
                      timeTo24 & " GMT"

    End Function


    Public Function UTCDate(ByVal dtDate)
        If Not IsDate(dtDate) Then Err.Raise 5
        dtDate = CDate(dtDate)
        Dim ZoneBias: ZoneBias = TimeZoneBias()
        If IsPDT(Now) <> IsPDT(dtDate) Then
            ZoneBias = ZoneBias - 60
        End If
        UTCDate = DateAdd("n", ZoneBias, dtDate)
    End Function

    Private Function IsPDT(ByVal dtDate)
        If Not IsDate(dtDate) Then Err.Raise 5
        dtDate = CDate(dtDate)
        Dim pdtLow, pdtUpr, nDaysBack

        pdtLow = DateSerial(Year(dtDate),  3, 31)
        pdtUpr = DateSerial(Year(dtDate), 10, 31)
        pdtLow = DateAdd("h", 2, pdtLow)
        pdtUpr = DateAdd("h", 2, pdtUpr)

        nDaysBack = Weekday(pdtLow) - 1
        If nDaysBack <> 0 Then
            pdtLow = DateAdd("d", -nDaysBack, pdtLow)
        End If

        nDaysBack = Weekday(pdtUpr) - 1
        If nDaysBack <> 0 Then
            pdtUpr = DateAdd("d", -nDaysBack, pdtUpr)
        End If

        IsPDT = (dtDate >= pdtLow And dtDate <= pdtUpr)
    End Function

    Private Function TimeZoneBias()
        Dim LTZone
        With GetObject("winmgmts:" & _
                "{impersonationLevel=impersonate}!\\.\root\cimv2")
            For Each LTZone In .ExecQuery(_
                    "Select * From Win32_ComputerSystem")
                TimeZoneBias = LTZone.CurrentTimeZone
            Next
        End With
        TimeZoneBias = TimeZoneBias * -1
    End Function

End Class

%>
...