Сопоставление паттернов с потоками в Racket? - PullRequest
Новая
       7

Сопоставление паттернов с потоками в Racket?

1 голос
/ 06 марта 2020

Сопоставление с образцом является очень удобочитаемой альтернативой ручной деструктуризации в предложениях let. Мне было интересно, возможно ли использовать его с потоками, как мы можем со списками.

В качестве иллюстрации рассмотрим простую реализацию add-between для создания последовательности с элементом, вставленным между каждым из элементов исходная последовательность. 

(define (add-between lst sep)
  (match lst
    ['() '()]
    [(cons v vs)
     (cons v
           (cons sep
                 (add-between vs sep)))]))

Использование: 

(add-between (list 'a 'b 'c) 'and) ; => '(a and b and c and)

Что если мы хотим сделать то же самое с произвольными последовательностями, такими как потоки? 

(define (add-between seq sep)
  (match seq
    ['() '()]
    [(cons v vs)
     (stream-cons v
                  (stream-cons sep
                               (add-between vs sep)))]))

Это приводит к ошибка: 

(add-between (stream 'a 'b 'c) 'and)
; match: no matching clause for #<stream>
; stdin:1:1
; Context:
;  /Applications/Racket v7.5/collects/racket/match/runtime.rkt:24:0 match:error
;  /Applications/Racket v7.5/collects/racket/repl.rkt:11:26

Было бы идеально, если бы мы могли сопоставить шаблон с типом последовательности c, так как это инкапсулирует списки и потоки.

1 Ответ

2 голосов
/ 06 марта 2020

Вы можете определить свои собственные формы сопоставления с образцом для потоков, используя define-match-expander, ? с предикатами и app с аксессорами. 

#lang racket
(require syntax/parse/define (prefix-in * racket/stream))
(define (stream-empty? v) (and (stream? v) (*stream-empty? v)))
(define (stream-cons? v) (and (stream? v) (not (*stream-empty? v))))

(define-match-expander stream-cons
  (syntax-parser
    [(_ fst rst) #'(? stream-cons? (app stream-first fst) (app stream-rest rst))])
  (syntax-parser
    [(_ fst rst) #'(*stream-cons fst rst)]))

(define-match-expander stream*
  (syntax-parser
    [(_ rst) #'rst]
    [(_ fst more ... rst) #'(stream-cons fst (stream* more ... rst))])
  (syntax-parser
    [(_ init ... rst) #'(*stream* init ... rst)]))

(define-match-expander stream
  (syntax-parser
    [(_) #'(? stream-empty?)]
    [(_ elem ...) #'(stream* elem ... (? stream-empty?))])
  (syntax-parser
    [(_ elem ...) #'(*stream elem ...)]))

Используя его: 

> (define (add-between seq sep)
    (match seq
      [(stream) (stream)]
      [(stream-cons v vs)
       (stream-cons v
                    (stream-cons sep
                                 (add-between vs sep)))]))
> (add-between (stream 'a 'b 'c) 'and)
#<stream>
> (stream->list (add-between (stream 'a 'b 'c) 'and))
'(a and b and c and)
...