Как настроить промежуточное ПО в Clojure, используя Reitit, чтобы включить приведение параметров тела? - PullRequest
Новая
       68

Как настроить промежуточное ПО в Clojure, используя Reitit, чтобы включить приведение параметров тела?

0 голосов
/ 07 марта 2020

Я пытаюсь установить маршрутизатор Reitit, который выполняет принуждение. Я могу заставить секцию ответа работать, но я не могу заставить принуждение тела работать должным образом. Ниже приведен код, который я использую: 

(ns example
  (:require
   [ring.middleware.json :refer [wrap-json-body wrap-json-response]]
   [ring.middleware.reload :refer [wrap-reload]]
   [ring.util.response :refer [response]]
   [reitit.ring.coercion :as rrc]
   [reitit.coercion.malli]
   [reitit.ring :as ring]))

(def router
  (ring/ring-handler
   (ring/router
    [["/healthz" {:get (fn [_] {:status 200 :body "healthy"})}]
     ["/api" {:coercion reitit.coercion.malli/coercion
              :middleware [rrc/coerce-exceptions-middleware
                           rrc/coerce-request-middleware
                           rrc/coerce-response-middleware]}
      ["/messages" {:post {:summary "Add a new message"
                           :parameters {:body [:map [:name string?]]}
                           :responses {200 {:body [:map
                                                   [:message string?]]}}
                           :handler (fn [req]
                                      {:status 200 :body {:message (:name (:body req))}})}}]]]
    {:data {:middleware []}})
   (ring/create-default-handler)))

(def app (-> #'router
             (wrap-reload)
             (wrap-json-response)
             (wrap-json-body {:keywords? true :bigdecimals? true})))

Принуждение не выполняется, даже когда я отправляю правильные параметры тела со следующей ошибкой: 

{
  "schema": "[:map {:closed true} [:name string?]]",
  "errors": [
    {
      "path": [],
      "in": [],
      "schema": "[:map {:closed true} [:name string?]]",
      "value": null,
      "type": "malli.core/invalid-type",
      "message": "invalid type"
    }
  ],
  "value": null,
  "type": "reitit.coercion/request-coercion",
  "coercion": "malli",
  "in": [
    "request",
    "body-params"
  ],
  "humanized": [
    "invalid type"
  ]
}

Это, кажется, указывает на то, что принуждение не может найти никаких параметров тела. Я предполагаю, что это связано с тем, как я настраиваю свое промежуточное программное обеспечение, но я не могу это исправить. Как настроить промежуточное программное обеспечение, чтобы в этом случае принудительная работа Reitit работала правильно?

1 Ответ

0 голосов
/ 07 марта 2020

Мне удалось заставить принуждение работать, удалив промежуточное программное обеспечение wrap- json -response и wrap- json -body и заменив его промежуточным программным обеспечением muuntaja следующим образом: 

(def router
  (ring/ring-handler
   (ring/router
    [["/healthz" {:get (fn [_] {:status 200 :body "healthy"})}]
     ["/api" {:coercion reitit.coercion.malli/coercion
              :middleware []}
      ["/messages" {:name ::message
                    :post {:summary "Add a new message"
                           :parameters {:body [:map [:name string?]]}
                           :responses {200 {:body [:map
                                                   [:message string?]]}}
                           :handler (fn [{:keys [parameters]}]
                                      {:status 200 :body {:message (:name (:body parameters))}})}}]]]
    {:data {:muuntaja m/instance
            :middleware [params/wrap-params
                         muuntaja/format-middleware
                         rrc/coerce-exceptions-middleware
                         rrc/coerce-request-middleware
                         rrc/coerce-response-middleware]}})
   (ring/create-default-handler)))
...