Постоянные двоичные данные в пользовательском компоненте - PullRequest
Новая
       47

Постоянные двоичные данные в пользовательском компоненте

3 голосов
/ 01 апреля 2020

Я делаю пользовательский компонент для хранения двоичных данных в программе. Какой тип данных может хранить и автоматически передавать двоичные данные в файл .DFM?

Я пробовал TBytes, но он не транслируется. String и AnsiString, но они не годятся для двоичных данных. Я пытаюсь избежать использования ручного подхода TReader / TWriter.

Ниже приведен небольшой фрагмент кода, описывающий проблему. BinProp (TBytes) не передается в файл Blob.bin, хотя свойство BinProp опубликовано: 

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.ExtCtrls;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

  tBlob = class (TComponent)
  private
    fBinProp : TBytes;
    fString : String;
    procedure SetBinProp(const Value: TBytes);
    procedure SetStringProp(const Value: String);
  public
  published
    property BinProp : TBytes read fBinProp write SetBinProp;
    property StringProp : String read fString write SetStringProp;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure tBlob.SetBinProp(const Value: TBytes);
begin
  fBinProp := Value;
end;

procedure tBlob.SetStringProp(const Value: String);
begin
  fString := Value;
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  Blob : tBlob;
  i : integer;
  Fs : TFileStream;
begin
  Blob := tBlob.Create(Self);
  SetLength(Blob.fBinProp, 10);
  for I := 0 to 9 do
    Blob.BinProp[I] := i;
  Blob.StringProp := '1234567890';
  Fs := TFileStream.Create('Blob.bin', fmCreate);
  Fs.WriteComponent(Blob);
  Fs.Free;
  Blob.Free;
  Fs := TFileStream.Create('Blob.bin', fmOpenRead);
  Blob := Fs.ReadComponent(nil) as TBlob;
  Caption :=
    'Length BinProp: '+IntToStr(Length(Blob.BinProp))+    //0
    ' - Length StringProp: '+IntToStr(Length(Blob.StringProp))+ // 10
    ' - Value StringProp: '+Blob.StringProp;   // 1234567890
  Fs.free;
end;

initialization
  RegisterClass(tBlob);
end.

1 Ответ

4 голосов
/ 01 апреля 2020

Нет типа данных, который автоматически передает двоичные данные в / из DFM. Вы должны передавать данные вручную. Сделайте так, чтобы ваш компонент переопределил виртуальный метод DefineProperties(), затем он может вызвать метод TFiler.DefineBinaryProperty() для предоставления пользовательских методов чтения / записи, которые при необходимости выполняют потоковую передачу двоичных данных.

См. Переопределение метода DefineProperties в DocWiki Embarcadero.

Например: 

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.ExtCtrls;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

  tBlob = class (TComponent)
  private
    fBinProp : TBytes;
    fString : String;
    procedure ReadBinProp(Stream: TStream);
    procedure WriteBinProp(Stream: TStream);
  protected
    procedure DefineProperties(Filer: TFiler); override;
  public
  published
    property BinProp : TBytes read fBinProp write fBinProp;
    property StringProp : String read fString write fString;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure tBlob.DefineProperties(Filer: TFiler);
begin
  inherited DefineProperties(Filer);
  Filer.DefineBinaryProperty('BinPropBytes', ReadBinProp, WriteBinProp, Length(fBinProp) > 0);
end;

procedure tBlob.ReadBinProp(Stream: TStream);
var
  BinSize: Integer;
begin
  BinSize := Stream.Size;
  SetLength(fBinProp, BinSize);
  if BinSize > 0 then
    Stream.ReadBuffer(PByte(fBinProp)^, BinSize);
end;

procedure tBlob.WriteBinProp(Stream: TStream);
begin
  Stream.WriteBuffer(PByte(fBinProp)^, Length(fBinProp));
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  Blob : tBlob;
  I : Integer;
  Fs : TFileStream;
begin
  Blob := tBlob.Create(nil);
  try
    SetLength(Blob.fBinProp, 10);
    for I := 0 to 9 do
      Blob.BinProp[I] := Byte(i);
    Blob.StringProp := '1234567890';
    Fs := TFileStream.Create('Blob.bin', fmCreate);
    try
      Fs.WriteComponent(Blob);
    finally
      Fs.Free;
    end;
    FreeAndNil(Blob);
    Fs := TFileStream.Create('Blob.bin', fmOpenRead or fmShareDenyWrite);
    try
      Blob := Fs.ReadComponent(nil) as TBlob;
    finally
      Fs.Free;
    end;
    Caption :=
      'Length BinProp: '+IntToStr(Length(Blob.BinProp))+    //0
      ' - Length StringProp: '+IntToStr(Length(Blob.StringProp))+ // 10
      ' - Value StringProp: '+Blob.StringProp;   // 1234567890
  finally
    Blob.Free;
  end;
end;

initialization
  RegisterClass(tBlob);

end.
...