Terraform: Su bnet в использовании лазурь - PullRequest
Новая
       10

Terraform: Su bnet в использовании лазурь

0 голосов
/ 21 января 2020

Сообщение об ошибке

При выполнении terraform apply появляется следующее сообщение об ошибке:

Ошибка: Ошибка создания / обновления виртуальной сети "CTI-NETWORK" (Resource Группа "CTI-RESOURCES"): network.VirtualNetworksClient # CreateOrUpdate: Ошибка отправки запроса: StatusCode = 400 - Исходная ошибка: Code = "InUseSubnetCannotBeDeleted" Message = "Su bnet CTI-PRD используется / subscription / d92e8f07- e127-4015-b67a-a547af76fdfc / resourceGroups / CTI-RESOURCES /айдеры / Microsoft.Network / networkInterfaces / CTI-NI C -PRD1 / ipConfigurations / CTI-IP-PRD1 и не могут быть удалены. Для удаления su bnet, удалите все ресурсы из су bnet. См. Aka.ms/deletesubnet. " Подробности = []

Я предполагаю, что у меня перепутана зависимость, но, похоже, не могу это выяснить.

Фрагмент кода

Содержимое main.tf 

provider "azurerm" {
    version         = "=1.38.0"
    subscription_id = "d92e8f07-e127-4015-b67a-a547af76fdfc"
}

resource "azurerm_resource_group" "resourcegroup" {
    name            = "${var.prefix}RESOURCES"
    location        = var.location
}

resource "azurerm_virtual_network" "network" {
    name                = "${var.prefix}NETWORK"
    resource_group_name = azurerm_resource_group.resourcegroup.name
    address_space       = ["10.0.0.0/16"]
    location            = var.location
}

resource "azurerm_subnet" "prd-subnet" {
    name                 = "${var.prefix}PRD"
    resource_group_name  = azurerm_resource_group.resourcegroup.name
    virtual_network_name = azurerm_virtual_network.network.name
    address_prefix       = "10.0.0.0/24"
}

resource "azurerm_subnet" "tst-subnet" {
    name                 = "${var.prefix}TST"
    resource_group_name  = azurerm_resource_group.resourcegroup.name
    virtual_network_name = azurerm_virtual_network.network.name
    address_prefix       = "10.0.1.0/24"
}

resource "azurerm_public_ip" "ip-prd-1" {
    name                = "${var.prefix}PIP-PRD1"
    resource_group_name = azurerm_resource_group.resourcegroup.name
    location            = var.location
    allocation_method   = "Dynamic"
    domain_name_label   = "vm-prd-1"
}


resource "azurerm_network_interface" "nic-prd-1" {
    name                = "${var.prefix}NIC-PRD1"
    resource_group_name = azurerm_resource_group.resourcegroup.name
    location            = var.location

    ip_configuration {
        name                          = "${var.prefix}IP-PRD1"
        subnet_id                     = azurerm_subnet.prd-subnet.id
        private_ip_address_allocation = "Dynamic"
        public_ip_address_id          = azurerm_public_ip.ip-prd-1.id
    }
}

resource "azurerm_virtual_machine" "vm-prd-1" {
    name                  = "${var.prefix}VM-PRD-1"
    location              = var.location
    resource_group_name   = azurerm_resource_group.resourcegroup.name
    network_interface_ids = [azurerm_network_interface.nic-prd-1.id]
    vm_size               = var.size

    delete_os_disk_on_termination    = true
    delete_data_disks_on_termination = true

    storage_image_reference {
        publisher         = "credativ"
        offer             = "Debian"
        sku               = "9-backports"
        version           = "latest"
    }

    storage_os_disk {
        name              = "lin-disk-1"
        caching           = "ReadWrite"
        create_option     = "FromImage"
        managed_disk_type = "Standard_LRS"
    }

    os_profile {
        computer_name  = "${var.prefix}IP-PRD1"
        admin_username = "ADM-ADV"
        admin_password = "!!W0rksh0p"
    }

    os_profile_linux_config {
        disable_password_authentication = false
    }

    tags = {
        environment = "Production"
        application = "CTI Core"
    }
}








resource "azurerm_public_ip" "ip-prd-2" {
    name                = "${var.prefix}PIP-PRD-2"
    resource_group_name = azurerm_resource_group.resourcegroup.name
    location            = var.location
    allocation_method   = "Dynamic"
    domain_name_label   = "vm-prd-2"
}


resource "azurerm_network_interface" "nic-prd-2" {
    name                = "${var.prefix}NIC-PRD-2"
    resource_group_name = azurerm_resource_group.resourcegroup.name
    location            = var.location

    ip_configuration {
        name                          = "${var.prefix}IP-PRD-2"
        subnet_id                     = azurerm_subnet.prd-subnet.id
        private_ip_address_allocation = "Dynamic"
        public_ip_address_id          = azurerm_public_ip.ip-prd-2.id
    }
}

resource "azurerm_virtual_machine" "vm-prd-chef" {
    name                  = "${var.prefix}VM-PRD-CHEF"
    location              = var.location
    resource_group_name   = azurerm_resource_group.resourcegroup.name
    network_interface_ids = [azurerm_network_interface.nic-prd-2.id]
    vm_size               = var.size

    delete_os_disk_on_termination    = true
    delete_data_disks_on_termination = true

    storage_image_reference {
        publisher         = "Canonical"
        offer             = "UbuntuServer"
        sku               = "18.04-LTS"
        version           = "latest"
    }

    storage_os_disk {
        name              = "lin-disk-2"
        caching           = "ReadWrite"
        create_option     = "FromImage"
        managed_disk_type = "Standard_LRS"
    }

    os_profile {
        computer_name  = "${var.prefix}IP-PRD-CHEF"
        admin_username = "XXX"
        admin_password = "XXX"
    }

    os_profile_linux_config {
        disable_password_authentication = false
    }

    tags = {
        environment = "Production"
        application = "CTI Service"
    }

    provisioner "remote-exec" {
        inline = [
            "touch /root/test.txt"
        ]
    }

}

Содержимое переменной .tf 

variable "prefix" {
    type            = string
    default         = "CTI-"
    description     = "Prefix of the resources"
}

variable "location" {
    type            = string
    default         = "westeurope"
    description     = "Location of the resources"
}

variable "size" {
    type            = string
    default         = "Standard_A1_v2"
    description     = "Size of the virtual machines"
}

Спасибо за помощь!

1 Ответ

0 голосов
/ 21 января 2020

С сообщением, которое вы предоставили, вы хотите создать другую виртуальную машину в существующей su bnet из Vnet. Поэтому вам нужно использовать ресурс данных вместо формата ресурса. Измените свой код Terraform следующим образом:

Измените: 

resource "azurerm_virtual_network" "network" {
    name                = "${var.prefix}NETWORK"
    resource_group_name = azurerm_resource_group.resourcegroup.name
    address_space       = ["10.0.0.0/16"]
    location            = var.location
}

resource "azurerm_subnet" "prd-subnet" {
    name                 = "${var.prefix}PRD"
    resource_group_name  = azurerm_resource_group.resourcegroup.name
    virtual_network_name = azurerm_virtual_network.network.name
    address_prefix       = "10.0.0.0/24"
}

Into: 

data "azurerm_virtual_network" "network" {
  name                = "${var.prefix}NETWORK"
  resource_group_name = azurerm_resource_group.resourcegroup.name
}

data "azurerm_subnet" "prd-subnet" {
    name = "${var.prefix}PRD"
    virtual_network_name = data.azurerm_virtual_network.network.name
    resource_group_name = azurerm_resource_group.resourcegroup.name
}

resource "azurerm_network_interface" "nic-prd-1" {
    name                = "${var.prefix}NIC-PRD1"
    resource_group_name = azurerm_resource_group.resourcegroup.name
    location            = var.location

    ip_configuration {
        name                          = "${var.prefix}IP-PRD1"
        subnet_id                     = data.azurerm_subnet.prd-subnet.id
        private_ip_address_allocation = "Dynamic"
        public_ip_address_id          = azurerm_public_ip.ip-prd-1.id
    }
}

Данные Terraform процитируют существующий ресурс и не изменяют их. Если другой su bnet tst-subnet также существует, вы можете изменить его, как указано выше.

...