Ярлыки серии динамических диаграмм

Question

У меня есть некоторый код Visual Basic, который создает диаграмму для каждой строки. Он устанавливает значения серии, используя этот код:

.SeriesCollection (1) .Values ​​= "=" & Ws.Name & "! R" & CurrRow & "C3: R" & CurrRow & "C8"

С чем я борюсь, как установить метки серий? Метки серии всегда будут 1-й строкой и будут в соответствующем столбце. Я знаю, что это намного проще, чем приведенный выше код, но я в тупике.

Любая помощь приветствуется.

Answer 1

Используйте Ws.Range ("C1: H1"). Значение в методе .SeriesCollection (1) .ApplyDataLabels.

Answer 2

Мой первый ответ интерпретировал вопрос как запрос названия серии. Если вы хотите использовать диапазон для меток данных, это немного сложнее.

Если у вас Excel 2013, вы можете напрямую назначить диапазон:

With .SeriesCollection(1)
  .ApplyDataLabels
  With .DataLabels
    .Format.TextFrame2.TextRange.InsertChartField _
        msoChartFieldRange, "='" & Ws.Name & "'!R1C3:R1C8", 0
    .ShowRange = True
    .ShowValue = False
  End With
End With

Если у вас более ранняя версия Excel, вам нужно пройтись по ярлыкам.

Назначает статический текст ячеек меткам:

Dim iPt As Long
Dim rLabels As Range

Set rLabels = Ws.Range(Ws.Cells(1, 3), Ws.Cells(1, 8))

With .SeriesCollection(1)
  .ApplyDataLabels
  For iPt = 1 To .Points.Count
    .Points(iPt).DataLabel.Text = rLabels.Cells(iPt).Text
  Next
End With

Это связывает каждую метку с соответствующей ячейкой, поэтому метка отражает любые изменения в ячейках:

Dim iPt As Long
Dim rLabels As Range

Set rLabels = Ws.Range(Ws.Cells(1, 3), Ws.Cells(1, 8))

With .SeriesCollection(1)
  .ApplyDataLabels
  For iPt = 1 To .Points.Count
    .Points(iPt).DataLabel.Text = "=" & rLabels.Cells(iPt).Address(, , , True)
  Next
End With

Answer 3

Я думаю, из вашей команды для значений Y вы хотите:

.SeriesCollection(1).Name = "=" & Ws.Name & "!R" & CurrRow & "C2"

- это та же строка, что и значения Y, столбец перед началом значений Y.