Можно ли реализовать многоступенчатую сортировку с помощью QUERY? - PullRequest
Новая
       7

Можно ли реализовать многоступенчатую сортировку с помощью QUERY?

1 голос
/ 15 февраля 2020

https://docs.google.com/spreadsheets/d/1XoxAY8MEgrGrpG1yJ2VthHDOGr6u2pBZC1YotpDfslE/edit?usp=sharing

Вкладка Deck Trends ячейка A3 содержит команду QUERY, где вы можете увидеть текущий порядок сортировки.

Что я я хочу добиться следующего:

Любая строка, где Col E равно 4, я бы хотел, чтобы сортировка вторичная основывалась на Col F

Все остальные строки Мне бы хотелось, чтобы вторичная сортировка основывалась на Col D (как она установлена ​​в настоящее время).

Возможно ли даже иметь несколько правил сортировки в одном QUERY?

1 Ответ

1 голос
/ 15 февраля 2020

try: 

=QUERY({QUERY({
 'Combined Opp Meta'!A2:G11; 'Combined Opp Meta'!A14:G23; 'Combined Opp Meta'!A26:G35},
 "where Col5 = 4
  order by Col5 desc,Col6 desc", 0);
 QUERY({
 'Combined Opp Meta'!A2:G11; 'Combined Opp Meta'!A14:G23; 'Combined Opp Meta'!A26:G35},
 "where Col5 <> 4
  order by Col5 desc,Col4 desc", 0)},
 "limit 12", 0)

Исправление литерала массива: 

=QUERY({IFERROR(QUERY({
 'Combined Opp Meta'!A2:G11; 'Combined Opp Meta'!A14:G23; 'Combined Opp Meta'!A26:G35},
 "where Col5 = 4
  order by Col5 desc,Col6 desc", 0), {"","","","","","",""});
 IFERROR(QUERY({
 'Combined Opp Meta'!A2:G11; 'Combined Opp Meta'!A14:G23; 'Combined Opp Meta'!A26:G35},
 "where Col5 <> 4
  order by Col5 desc,Col4 desc", 0), {"","","","","","",""})},
 "where Col1 is not null limit 12", 0)
...