XSLT для неявного удаления элементов - PullRequest
Новая
       11

XSLT для неявного удаления элементов

0 голосов
/ 23 апреля 2020

Я пытаюсь создать таблицу стилей для копирования элемента <body> для вывода и неявного удаления всех других элементов.

Источник: 

<!-- language: lang-xml -->
<?xml version="1.0" encoding="UTF-8"?>
<document>
    <info>trial</info>
    <style>unknown</style>
    <body>
        <section>
            <p>para 1</p>
            <p>para 2</p>
        </section>
    </body>
</document>

Требуемый вывод: 

<!-- language: lang-xml -->
<?xml version="1.0" encoding="UTF-8"?>
<document>
    <body>
        <section>
            <p>para 1</p>
            <p>para 2</p>
        </section>
    </body>
</document>

XSLT: 

<!-- language: lang-xsl -->
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" encoding="UTF-8"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>       

    <xsl:template match="node()[not(descendant-or-self::body)]"/>

</xsl:stylesheet>

Выход вышеупомянутого XSLT: 

<!-- language: lang-xml -->
<?xml version="1.0" encoding="UTF-8"?>
<document>
    <body/>
</document>

Ps Я новичок ie в XSLT. Если бы вы могли объяснить свое решение и указать мне подходящий ресурс для изучения xpath и xslt 1.0, это спасет вас!

Ответы [ 2 ]

1 голос
/ 23 апреля 2020

Ну, section не имеет потомка body, поэтому он соответствует вашему шаблону и удален. Вы, вероятно, хотели написать [not(ancestor-or-self::body)] - но это также включало бы root document, поэтому результат будет пустым. Почему бы просто не сделать: 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="document">
    <xsl:copy>
        <xsl:apply-templates select="body"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

или даже проще: 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/document">
    <xsl:copy>
        <xsl:copy-of select="body"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>
0 голосов
/ 23 апреля 2020

Вот как ты мог это сделать. Я добавил несколько комментариев / объяснений в комментарии. 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    version="1.0">

  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="document">
      <xsl:copy> <!-- copy the current node (not its content) -->
          <xsl:apply-templates select="body"/> <!-- Apply templates to selected node -->
      </xsl:copy>
  </xsl:template>

  <!-- Identity template. Ref : https://en.wikipedia.org/wiki/Identity_transform -->
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

Посмотрите, как это работает здесь: https://xsltfiddle.liberty-development.net/bEzknsS

Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...