Ошибка создания ответа интеграции шлюза API: NotFoundException: указан неверный идентификатор интеграции

Question

Цель

Решение или способ ее решения.

Проблема

Интеграция шлюза Terraform API с Firehose ниже работает, если Firehose создается отдельно заранее.

resource "aws_api_gateway_integration" "click_put" {
  rest_api_id = data.aws_api_gateway_rest_api.mysfit.id
  resource_id = aws_api_gateway_resource.click.id
  type        = "AWS"
  uri         = "arn:aws:apigateway:${var.REGION}:firehose:action/PutRecord"
  credentials = aws_iam_role.api_click.arn

  http_method = aws_api_gateway_method.click_put.http_method
  integration_http_method = "POST"
  request_parameters = {
    "integration.request.header.Content-Type" = "'application/x-amz-json-1.1'"
  }
  passthrough_behavior = "NEVER"
  request_templates = {
    "application/json" = <<EOF
{
  "DeliveryStreamName": "${local.firehose_name}",
  "Record": {
    "Data": "$util.base64Encode($input.json('$'))"
  }
}
EOF
  }
}
...
resource "aws_api_gateway_integration_response" "click_put" {
  rest_api_id = data.aws_api_gateway_rest_api.mysfit.id
  resource_id = aws_api_gateway_resource.click.id
  http_method = aws_api_gateway_method.click_put.http_method
  status_code = aws_api_gateway_method_response.click_put.status_code
  response_parameters = {
    "method.response.header.Access-Control-Allow-Origin" = "'*'"
  }
}

Однако, если они созданы в одном и том же модуле root, это вызывает ошибку.

Error creating API Gateway Integration Response: NotFoundException: Invalid Integration identifier specified

  on api_click.tf line 185, in resource "aws_api_gateway_integration_response" "click_put":
 185: resource "aws_api_gateway_integration_response" "click_put" {

Answer 1

Обходной путь / решение

Поместите зависимость в aws_api_gateway_integration от ресурса, вызывающего «NotFoundException: Указан неверный идентификатор интеграции».

resource "aws_api_gateway_integration_response" "click_put" {
  rest_api_id = data.aws_api_gateway_rest_api.mysfit.id
  resource_id = aws_api_gateway_resource.click.id
  http_method = aws_api_gateway_method.click_put.http_method
  status_code = aws_api_gateway_method_response.click_put.status_code
  response_parameters = {
    "method.response.header.Access-Control-Allow-Origin" = "'*'"
  }

  depends_on = [
    aws_api_gateway_integration.click_put
  ]
}

Ссылки

Есть указания что depen_on aws_api_gateway_integration или размещение ожидания будет способом.

Вероятно, ожидание полного завершения ресурса aws_api_gateway_integration было бы рекомендуемой практикой.

• aws_api_gateway_integration_response

  Примечание. Зависит от наличия aws_api_gateway_integration в ваших остальных API. Чтобы убедиться в этом, вам может понадобиться добавить явный зависящий от переменной_on для чистых запусков.

• Проблема интеграции шлюза API - указан неверный идентификатор метода Ошибка # 4001

  Я использую следующий обходной путь для решения аналогичной проблемы. Я получаю ошибку идентификатора неверного метода при первом запуске, когда все ресурсы создаются во время одного и того же применения. Создается прокси API для Lambda:

resource "aws_api_gateway_resource" "proxy" {
  rest_api_id = aws_api_gateway_rest_api.rest-api.id
  parent_id   = aws_api_gateway_rest_api.rest-api.root_resource_id
  path_part   = "{proxy+}"
}

resource "null_resource" "method-delay" {
  provisioner "local-exec" {
    command = "sleep 5"
  }
  triggers = {
    response = aws_api_gateway_resource.proxy.id
  }
}

resource "aws_api_gateway_method_response" "response" {
  depends_on = [null_resource.method-delay]
  http_method = "ANY"
  resource_id = aws_api_gateway_resource.proxy.id
  rest_api_id = aws_api_gateway_rest_api.rest-api.id
}