Как я могу определить, имеет ли объект или ссылка допустимое приведение строки? - PullRequest
Новая
       10

Как я могу определить, имеет ли объект или ссылка допустимое приведение строки?

6 голосов
/ 08 апреля 2010

Я столкнулся с ситуацией (при регистрации различных изменений данных), когда мне нужно определить, имеет ли ссылка допустимое приведение строки (например, может ли она быть правильно напечатана в журнале или сохранена в базе данных). В Scalar :: Util нет ничего для этого, поэтому я собрал что-то, используя другие методы в этой библиотеке: 

use strict;
use warnings;

use Scalar::Util qw(reftype refaddr);

sub has_string_coercion
{
    my $value = shift;

    my $as_string = "$value";
    my $ref = ref $value;
    my $reftype = reftype $value;
    my $refaddr = sprintf "0x%x", refaddr $value;

    if ($ref eq $reftype)
    {
        # base-type references stringify as REF(0xADDR)
        return $as_string !~ /^${ref}\(${refaddr}\)$/;
    }
    else
    {
        # blessed objects stringify as REF=REFTYPE(0xADDR)
        return $as_string !~ /^${ref}=${reftype}\(${refaddr}\)$/;
    }
}

# Example:
use DateTime;
my $ref1 = DateTime->now;
my $ref2 = \'foo';

print "DateTime has coercion: " . has_string_coercion($ref1) . "\n\n";
print "scalar ref has coercion: " . has_string_coercion($ref2) . "\n";

Однако я подозреваю, что может быть лучший способ определить это, осмотрев кишки переменной каким-либо образом. Как это можно сделать лучше?

1 Ответ

6 голосов
/ 08 апреля 2010

с перегрузка perldoc :

overload::StrVal(arg)

Дает строковое значение arg как при отсутствии перегрузки stringify. 

sub can_stringify {
    my ($obj) = @_;
    return "$obj" ne overload::StrVal($obj);
}

Обратите внимание, что overload::Method здесь не подходит , потому что :

  1. 'bool', '""', '0+',

Если одна или две из этих операций не перегружены, вместо них можно использовать оставшиеся.

Поэтому проверка только в том случае, если '""' перегружен, вернет ложные отрицания по сравнению с методом, который вы указали в своем вопросе.

...