Этот сюжет типичен для gnuplot?

Question

Я смотрю на https://stats.stackexchange.com/tags/data-visualization/info и мне кажется, что, может быть, я смогу найти ответ здесь ... или, может быть, это не так c и здесь.

Типичен ли этот сюжет для gnuplot?

Источник: https://arxiv.org/pdf/2003.10405.pdf

Answer 1

Это не по умолчанию внешний вид gnuplot. Но gnuplot вполне настраиваем, и внешний вид зависит от возможностей используемого устройства вывода (terminal) и библиотек, с которыми оно было построено.

Нередко у вас есть собственный ~/.gnuplot или всего сайта /usr/local/share/gnuplot/<version>/gnuplotrc. Из встроенной справки:

Когда gnuplot запущен, он сначала ищет общесистемный файл инициализации gnuplotrc. Расположение этого файла определяется при сборке программы и сообщается show loadpath. Затем программа ищет в каталоге пользователя HOME файл с именем .gnuplot в Unix -подобных системах или GNUPLOT.INI в других системах. (OS / 2 будет искать его в каталоге, указанном в переменной среды GNUPLOT; Windows будет использовать APPDATA).

Если вы не являетесь студентом, который должен следовать стилю вашего учебного заведения Руководство, я бы посоветовал вам разработать собственный стиль (ы) на основе примеров, которые вы можете найти в Интернете, и ваших потребностей.

Информация и примеры, доступные на gnuplotting.org , очень ценны для этой цели.

Answer 2

Как сказал @ Роланд Смит , gnuplot вполне настраиваемо. Чтобы понять, насколько это настраиваемо, см. Ниже полный пример, который воспроизводит нужный участок.

reset
set encoding utf8
# ***** TERMINAL SETTINGS *****
set terminal wxt size 800,450 font "Consolas"
# ***** GENERAL SETTINGS *****
# tics, key, and border
set tics nomirror scale 1.5
unset key
set border 7
# linestyles
set style line 1 lc "black"
set style line 2 lc "red"
# margins
set lmargin screen 0.100
set rmargin screen 0.900
set bmargin screen 0.135
# xlabel, xrange, and (m)xtics
set xlabel "Time [sec]"
set xrange [0:2.2]
set xtics 0.2 tc ls 1
set mxtics 4
# ***** CREATING SOME DATA TO PLOT *****
# Gaussian function plus some noise
f(x,a,b,c) = a*exp(-(x-b)**2/(2*c**2)) + a*0.02*rand(0)
# Storing on datablock
# First one
set table $FlowData
    plot f(x, 80.0, 0.25, 0.15)
unset table
# Second one
set table $PressureData
    plot f(x, 35.0, 0.75, 0.20)
unset table
# ***** THE PLOTS *****
# Turning-on the multiplot mode to place both plots
set multiplot
    # ***** FIRST PLOT SETTINGS *****
    set ylabel "Flow [l/min]"
    set yrange [-10:120]
    set mytics 4
    # Fist plot itself
    plot $FlowData axes x1y1 w l ls 1 lw 2
    # ***** SECOND PLOT SETTINGS *****
    # Remove previous customizations
    unset tics
    unset xlabel
    unset ytics
    unset ylabel
    # New customizations
    set border 8 ls 2
    set y2label "Pressure [mbar]" tc ls 2
    set y2range [-5:60]
    set y2tics tc ls 2
    set my2tics 4 
    # Labels
    set label "Compliance           : 15 [ml/mbar]"    at 0.95,100.0 offset 0, 0
    set label "Resistance           :  5 [mbar/l/sec]" at 0.95,100.0 offset 0,-1
    set label "PEEP                 :  5 [mbar]"       at 0.95,100.0 offset 0,-2
    set label "Inspiratory Pressure : 30 [mbar]"       at 0.95,100.0 offset 0,-3
    # Second plot itself
    plot $PressureData axes x1y2 w l ls 2 lw 2
unset multiplot 

Результат:

Answer 3

По умолчанию шрифт обычно выглядит иначе, а заголовки осей центрированы.