Terraform 0.12 Создание правил входа по шаблону - PullRequest
Новая
       9

Terraform 0.12 Создание правил входа по шаблону

1 голос
/ 19 февраля 2020

Интересно, можно ли использовать что-то подобное? У меня работает функциональный код, но так как пакеты в kubernetes будут быстро расти, я хочу преобразовать их в шаблоны. Это пример создания каждого nginx правила входа для каждого модуля WordPress сайта.

Теперь у каждого модуля есть входная запись WordPress с: 

resource "kubernetes_ingress" "ingress_nginx_siteA" {
  metadata {
    name        = "ingress-nginx-siteA"
    namespace   = "default"
    annotations = { "kubernetes.io/ingress.class" = "nginx", "nginx.ingress.kubernetes.io/configuration-snippet" = "modsecurity_rules '\n SecRuleEngine On\n SecRequestBodyAccess On\n SecAuditEngine RelevantOnly\n SecAuditLogParts ABCIJDEFHZ\n SecAuditLog /var/log/modsec_audit.log\n SecRuleRemoveById 932140\n';\n", "nginx.ingress.kubernetes.io/ssl-passthrough" = "true" }
  }
  spec {
    tls {
      hosts       = ["siteA.test.com"]
      secret_name = "wildcard-test-com"
    }
    rule {
      host = "siteA.test.com"
      http {
        path {
          path = "/"
          backend {
            service_name = "siteA"
            service_port = "80"
          }
        }
      }
    }
  }
}

Теперь я хочу разделить на variables.tf , который содержит целые переменные сайтов, файл шаблона rules.tpl и main.tf , которые управляют этим материалом.

variables.tf: 

variable "wordpress_site" {
  type = map(object({
    name        = string
    url         = string
    certificate = string
  }))
    default = {
    siteA = {
      name        = siteA
      url         = siteA.test.com
      certificate = wildcard-test-com
    }
    siteB = {
      name        = siteB
      url         = siteB.test.com
      certificate = wildcard-test-com
    }
  }
}

rules.tpl: 

%{ for name in wordpress_site.name ~}
resource "kubernetes_ingress" "ingress_nginx_${name}" {
  metadata {
    name        = "ingress-nginx-${name}"
    namespace   = "default"
    annotations = { "kubernetes.io/ingress.class" = "nginx", "nginx.ingress.kubernetes.io/configuration-snippet" = "modsecurity_rules '\n SecRuleEngine On\n SecRequestBodyAccess On\n SecAuditEngine RelevantOnly\n SecAuditLogParts ABCIJDEFHZ\n SecAuditLog /var/log/modsec_audit.log\n SecRuleRemoveById 932140\n';\n", "nginx.ingress.kubernetes.io/ssl-passthrough" = "true" }
  }
  spec {
    tls {
      hosts       = ["${wordpress_site.url}"]
      secret_name = "${wordpress_site.certificate}"
    }
    rule {
      host = "${wordpress_site.url}"
      http {
        path {
          path = "/"
          backend {
            service_name = "${name}"
            service_port = "80"
          }
        }
      }
    }
  }
}
%{ endfor ~}

и теперь, как в main.tf, как лучше всего смешать все это? Я вижу, что в TF 0.12 добавлены новые функции, такие как функция templatefile, но я даже не знал, смогу ли я использовать его следующим образом:

main.tf: 

templatefile(${path.module}/rules.tpl, ${module.var.wordpress_site})

Спасибо всем за ваша поддержка!

1 Ответ

0 голосов
/ 19 февраля 2020

Функция templatefile предназначена для генерации строк из шаблона, а не для генерации конфигурации Terraform. Несмотря на то, что будет возможно отобразить данный шаблон для получения строки, содержащей конфигурацию Terraform, Terraform будет видеть результат как обычную строку, а не как дополнительную конфигурацию для оценки.

Вместо этого нам нужно получить желаемый результат - ресурс for_each, который позволяет создавать несколько экземпляров из одного ресурса на основе значения карты. 

resource "kubernetes_ingress" "nginx" {
  for_each = var.wordpress_site

  metadata {
    name        = "ingress-nginx-${each.value.name}"
    namespace   = "default"
    annotations = {
      "kubernetes.io/ingress.class" = "nginx"
      "nginx.ingress.kubernetes.io/configuration-snippet" = <<-EOT
        modsecurity_rules '
         SecRuleEngine On
         SecRequestBodyAccess On
         SecAuditEngine RelevantOnly
         SecAuditLogParts ABCIJDEFHZ
         SecAuditLog /var/log/modsec_audit.log
         SecRuleRemoveById 932140
        ';
      EOT
      "nginx.ingress.kubernetes.io/ssl-passthrough" = "true"
    }
  }
  spec {
    tls {
      hosts       = [each.value.url]
      secret_name = each.value.certificate
    }
    rule {
      host = each.value.url
      http {
        path {
          path = "/"
          backend {
            service_name = each.value.name
            service_port = "80"
          }
        }
      }
    }
  }
}

Когда для ресурса установлено for_each, Terraform будет оцените данный аргумент, чтобы получить карту, а затем создайте один экземпляр ресурса для каждого элемента в этой карте, каждый из которых будет определен соответствующим ключом карты. В этом случае, принимая значение по умолчанию var.wordpress_site, вы получите два экземпляра со следующими адресами:

  • kubernetes_ingress.nginx["siteA"]
  • kubernetes_ingress.nginx["siteB"]

Внутри блока resource ссылки, начинающиеся с each.value, относятся к значениям на карте, которые в данном случае являются объектами, описывающими каждый сайт.

...