Обновить запрос по элементу, выбранному из списка - событие двойного щелчка

Question

У меня есть форма с именем ConsultaInfo, в которой отображается список (LNome) всех имен партнеров, и я хочу выполнить запрос, который вернет в ту же форму всю остальную информацию из имени выбранного партнера из этот список.

Мое намерение состоит в том, чтобы, когда я дважды щелкну имя партнера, будет запущен запрос (ConsultaSocio), приносящий все остальные личная информация от выбранного партнера из Таблицы Socios, и затем эта информация будет отображаться на правой стороне той же формы.

Поэтому я хотел бы знать, как я могу выполнить sh что?

Любая помощь будет высоко ценится

Answer 1

Есть несколько способов сделать это, каждый из которых предполагает, что в дополнение к имени, отображаемому в окне списка, есть также поле идентификатора.

Если форма связана с запросом, затем вы можете использовать .RecordsetClone, чтобы найти соответствующую запись, а затем установить позицию формы:

Private Sub lstName_DblClick(Cancel As Integer)
    On Error GoTo E_Handle
    Me.RecordsetClone.FindFirst "ID=" & Me!lstName
    Me.Bookmark = Me.RecordsetClone.Bookmark
sExit:
    On Error Resume Next
    Exit Sub
E_Handle:
    MsgBox Err.Description & vbCrLf & vbCrLf & "ConsultaInfo!lstName_DblClick", vbOKOnly + vbCritical, "Error: " & Err.Number
    Resume sExit
End Sub

Другой вариант - изменить свойство RecordSource формы, чтобы иметь только эту запись:

Private Sub lstName_DblClick(Cancel As Integer)
    On Error GoTo E_Handle
    Me.RecordSource = "SELECT * FROM Socio WHERE ID=" & Me!lstName
sExit:
    On Error Resume Next
    Exit Sub
E_Handle:
    MsgBox Err.Description & vbCrLf & vbCrLf & "ConsultaInfo!lstName_DblClick", vbOKOnly + vbCritical, "Error: " & Err.Number
    Resume sExit
End Sub

С уважением,