Не удается правильно передать параметры пакетного скрипта в команду внутри оператора al oop

Question

У меня проблема с передачей параметров командам внутри скрипта, который загружает онлайн-поток в отдельный каталог, а затем исправляет ошибки с помощью ffmpeg.

Сначала я проверяю, существует ли каталог, а если нет, то создаю его:

if exist %1 (
      echo Directory exists
   ) ELSE (
      mkdir "%1%"
      echo Directory created
   )

А затем есть основной l oop, который пытается загрузить поток и исправить в нем ошибки.

for /L %%C in (1,1,10000) do (

      streamlink -o "%%1\%%1%%C.mp4" "some.url/%2" best   
      if exist %1\%1%C.mp4 (
          d:\streamlink\ffmpeg\bin\ffmpeg.exe -loglevel debug -i "%1\%1%C.mp4" -c:v copy -c:a copy "%1\%1%C_o.mp4" 1>"%1%\log\%1%%C.log" 2>"%1%\err\%1%%C.err"
         )
      timeout /T 300 
    )

Так, например, если я выполню:

script.cmd foo xyz

, то в первом l oop должно быть выполнено:

streamlink -o "foo\foo1.mp4" "some.url/xyz" best   
      if exist foo\foo1.mp4 (
          d:\streamlink\ffmpeg\bin\ffmpeg.exe -loglevel debug -i "foo\foo1.mp4" -c:v copy -c:a copy "foo\foo1_o.mp4" 1>"foo\log\foo1.log" 2>"foo\err\foo1.err"
         )

Не могли бы вы помочь мне с это?

Answer 1

Пожалуйста, откройте командную строку , запустите call /? и прочитайте справку по выводу, объясняющую, как на аргументы пакетного файла можно ссылаться из пакетного файла. Аргумент 0 - это пакетный файл, который в настоящее время обрабатывается cmd.exe.

. Я предлагаю этот пакетный файл для задачи, хотя и не знаю, что на самом деле делает FOR l oop.

@echo off
setlocal EnableExtensions DisableDelayedExpansion

if "%~1" == "" (
    echo ERROR: %~nx0 must be called with a directory path as first argument.
    goto EndBatch
)

if "%~2" == "" (
    echo ERROR: %~nx0 must be called with ??? as second argument.
    goto EndBatch
)

rem Assign the directory path to an environment variable.
set "DirectoryPath=%~1"
rem Make sure the directory path contains \ and not / as directory separator.
set "DirectoryPath=%DirectoryPath:/=\%"
rem Make sure the directory path ends with a backslash.
if not "%DirectoryPath:~-1%" == "\" set "DirectoryPath=%DirectoryPath%\"

rem Check if the directory exists already and create it otherwise.
if exist "%DirectoryPath%" (
      echo Directory exists.
) else (
    md "%DirectoryPath%"
    if exist "%DirectoryPath%" (
        echo Directory created.
    ) else (
        echo ERROR: %~nx0 failed to create directory "%DirectoryPath:~0,-1%"
        goto EndBatch
    )
)

rem Get name of last directory from directory path for the various file names.
for %%I in ("%DirectoryPath:~0,-1%") do (
    set "VideoFileName=%DirectoryPath%%%~nxI"
    set "StdLogFileName=%DirectoryPath%log\%%~nxI
    set "ErrLogFileName=%DirectoryPath%err\%%~nxI
)

rem Create the two additional subdirectories with suppressing the
rem error messages output on these directories existing already.
md "%DirectoryPath%log" 2>nul
md "%DirectoryPath%err" 2>nul

for /L %%I in (1,1,10000) do (
    streamlink.exe -o "%VideoFileName%%%I.mp4" "some.url/%~2" best
    if not errorlevel 1 if exist "%VideoFileName%%%I.mp4" (
        "D:\streamlink\ffmpeg\bin\ffmpeg.exe" -loglevel debug -i "%VideoFileName%%%I.mp4" -c:v copy -c:a copy "%VideoFileName%%%I_o.mp4" >"%StdLogFileName%%%I.log" 2>"%ErrLogFileName%%%I.log"
    )
    rem Don't know what this wait is for.
    %SystemRoot%\Sytem32\timeout.exe /T 300
)

rem Remove all empty standard log files.
for %%I in ("%StdLogFileName%*.log") do if %%~zI == 0 del "%%I"
rem Remove the standard log file directory on being empty now.
rd "%DirectoryPath%log" 2>nul

rem Remove all empty error log files.
for %%I in ("%ErrLogFileName%*.log") do if %%~zI == 0 del "%%I"
rem Remove the error log file directory on being empty now.
rd "%DirectoryPath%err" 2>nul

:EndBatch
echo/
endlocal
pause

Чтобы понять используемые команды и то, как они работают, откройте окно командной строки *1013*, выполните там следующие команды и полностью прочитайте все страницы справки, отображаемые для каждой команды.

• del /?
• echo /?
• endlocal /?
• for /?
• goto /?
• if /?
• md /?
• pause /?
• rd /?
• rem /?
• set /?
• setlocal /?
• timeout /?

См. Также:

• Статья Microsoft о Использование операторов перенаправления команд
• Форум DosTips topi c: ECHO. Не удается дать текст или пустую строку - вместо этого используйте ECHO /