Объединить список карт и объединить значения с наборами в Clojure

Question

Какую функцию я могу поставить здесь как FOO , чтобы получить значение true в конце? Я играл с хэш-набором (корректно только для первых двух значений), коннектом и конкатом, но я знаю, что не справляюсь с одноэлементным или заданным условием правильно с любым из них.

(defn mergeMatches [propertyMapList]
    "Take a list of maps and merges them combining values into a set"
    (reduce #(merge-with FOO %1 %2) {} propertyMapList))

(def in 
    (list
        {:a 1}
        {:a 2}
        {:a 3}
        {:b 4}
        {:b 5}
        {:b 6} ))

(def out
    { :a #{ 1 2 3}
      :b #{ 4 5 6} })

; this should return true
(= (mergeMatches in) out)

Какой самый идиоматический способ справиться с этим?

Answer 1

Это будет делать:

(let [set #(if (set? %) % #{%})]
  #(clojure.set/union (set %) (set %2)))

Переписать более прямо для примера (Алекс):

(defn to-set [s]
    (if (set? s) s #{s}))
(defn set-union [s1 s2] 
    (clojure.set/union (to-set s1) (to-set s2)))
(defn mergeMatches [propertyMapList]
    (reduce #(merge-with set-union %1 %2) {} propertyMapList))

Answer 2

Я не писал этого, но он способствовал @ amitrathore на Twitter :

(defn kv [bag [k v]] 
  (update-in bag [k] conj v))
(defn mergeMatches [propertyMapList]
  (reduce #(reduce kv %1 %2) {} propertyMapList))

Answer 3

Я бы не использовал для этого слияние,

(defn fnil [f not-found]
  (fn [x y] (f (if (nil? x) not-found x) y)))
(defn conj-in [m map-entry]
  (update-in m [(key map-entry)] (fnil conj #{}) (val map-entry)))
(defn merge-matches [property-map-list]
  (reduce conj-in {} (apply concat property-map-list)))

user=> (merge-matches in)
{:b #{4 5 6}, :a #{1 2 3}}

fnil скоро станет частью ядра, так что вы можете игнорировать реализацию ... но он просто создает версию другой функции, которая может обрабатывать ноль аргументов. В этом случае coni будет заменять # {} на ноль.

Таким образом, сокращение соединяется с набором для каждого ключа / значения в списке предоставленных карт.

Answer 4

Другое решение, предоставленное @ wmacgyver на Twitter на основе мультикарты :

(defn add
  "Adds key-value pairs the multimap."
  ([mm k v]
     (assoc mm k (conj (get mm k #{}) v)))
  ([mm k v & kvs]
     (apply add (add mm k v) kvs)))
(defn mm-merge
  "Merges the multimaps, taking the union of values."
  [& mms]
  (apply (partial merge-with union) mms))   

(defn mergeMatches [property-map-list]
  (reduce mm-merge (map #(add {} (key (first %)) (val (first %))) property-map-list)))      

Answer 5

Это похоже на работу:

(defn FOO [v1 v2]
      (if (set? v1)
          (apply hash-set v2 v1)
          (hash-set v1 v2)))

Answer 6

Не очень красиво, но это работает.

(defn mergeMatches [propertyMapList]
    (for [k (set (for [pp propertyMapList] (key (first pp))))]
         {k (set (remove nil? (for [pp propertyMapList] (k pp))))}))