XSLT 1.0 Muenchian групповая реализация не работает

Question

Рабочая реализация XSLT 2.0:

<xsl:template name="SummaryRows">
    <xsl:for-each-group select="//Item/ItemGroup/ItemEntry" group-by="Description">
        <tr>
            <td>
                <xsl:value-of select="current-grouping-key()"/>
            </td>
            <td></td>
            <td>
                <xsl:call-template name="formatNumber2">
                    <xsl:with-param name="number" select="format-number(number(sum(current-group()/ItemSum/text())), '#.##')"/>
                </xsl:call-template>
            </td>
        </tr>
    </xsl:for-each-group>
</xsl:template>

Попытка реализовать Мюнхенская группировка :

<xsl:key name="items-by-description" match="ItemEntry" use="Description"/>
<xsl:template name="SummaryRows">
            <xsl:for-each select="//Item/ItemGroup/ItemEntry[count(. | key('items-by-description', Description)[1]) = 1]">
                <xsl:variable name="current-grouping-key" select="Description"/>
                <xsl:variable name="current-group" select="key('items-by-description', $current-grouping-key)"/>

                <xsl:for-each select="$current-group">
                    <tr>
                        <td>
                            <xsl:value-of select="$current-grouping-key"/>
                        </td>
                        <td/>
                        <td align="right">
                                <xsl:call-template name="formatNumber2">
                                    <xsl:with-param name="number" select="format-number(number(sum(./ItemSum/text())), '#.##')"/>
                                </xsl:call-template>
                        </td>
                    </tr>
                </xsl:for-each>
            </xsl:for-each>

</xsl:template>

Пример xml фрагмент:

     <Item>
      <ItemGroup groupId="1">
        <ItemEntry>
          <Description>A</Description>
          <ItemSum>6301.1</ItemSum>
        </ItemEntry>
        <ItemEntry>
          <Description>B</Description>
          <ItemSum>901.1</ItemSum>
        </ItemEntry>
      </ItemGroup>
      <ItemGroup groupId="2">
        <ItemEntry>
          <Description>C</Description>
          <ItemSum>631.1</ItemSum>
        </ItemEntry>
        <ItemEntry>
          <Description>A</Description>
          <ItemSum>9.1</ItemSum>
        </ItemEntry>
      </ItemGroup>
    </Item>

Должен возвращаться список ItemEntry Description (который предполагается текущим-grouping-key () в xslt 2.0). Для каждой такой группы она должна иметь сумму всех ItemSum этой группы.

Пример результата:

    A           6310.2
    B           901.1
    C           631.1

<xsl:for-each select="$current-group"> l oop не выполняется, что приводит к пустому набору. Чего не хватает в реализации?

Обновление:

Среда Java 8

Свойства / инициализация фабрики преобразования:

System.setProperty("javax.xml.transform.TransformerFactory", "com.sun.org.apache.xalan.internal.xsltc.trax.TransformerFactoryImpl");
            System.setProperty(XPathFactory.DEFAULT_PROPERTY_NAME + ":" + XPathFactory.DEFAULT_OBJECT_MODEL_URI,
                    "org.apache.xpath.jaxp.XPathFactoryImpl");

            XPathFactory xpf = XPathFactory.newInstance();

Answer 1

Как я уже сказал в комментарии, вам не нужно два вложенных for-each элемента для замены одного for-each-group, вы просто используете один, тогда минимальная выборка будет

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"

    version="1.0">

  <xsl:output method="html" indent="yes" doctype-system="about:legacy-doctype"/>

<xsl:key name="items-by-description" match="ItemEntry" use="Description"/>

<xsl:template match="/*">
            <xsl:for-each select="//Item/ItemGroup/ItemEntry[count(. | key('items-by-description', Description)[1]) = 1]">
                <xsl:variable name="current-grouping-key" select="Description"/>
                <xsl:variable name="current-group" select="key('items-by-description', $current-grouping-key)"/>


                    <tr>
                        <td>
                            <xsl:value-of select="$current-grouping-key"/>
                        </td>
                        <td/>
                        <td align="right">
                                <xsl:value-of select="format-number(number(sum($current-group/ItemSum/text())), '#.##')"/>
                        </td>
                    </tr>
            </xsl:for-each>

</xsl:template>

https://xsltfiddle.liberty-development.net/3MvmXiv/3 и выведет три tr элемента для вашего образца, точно так же, как подход XSLT 2 https://xsltfiddle.liberty-development.net/3MvmXiv/0