attiny85 бит взрыва Uart с Arduino - PullRequest
Новая
       78

attiny85 бит взрыва Uart с Arduino

0 голосов
/ 08 апреля 2020

Я попытался реализовать TX UART только для ATTiny85 и получить биты, используя Arduino Micro. ( похожий вопрос не помог, поскольку он сильно отличается от моей ситуации)

Я намерен печатать через консоль attiny85 -> arduino ->, чтобы я мог отлаживать attiny85, поскольку у меня нет в наличии осциллографа.

Предохранители attiny85: "efuse:w:0xff:m -U hfuse:w:0xdf:m -U lfuse:w:0xf1:m" aka. 16-МГц F_CPU arduino, похоже, также имеет 16-МГц F_CPU

Похожий на упомянутый вопрос attiny85 отправляет биты по таймеру 0 ISR один бит за раз: 

#ifndef F_CPU
#define F_CPU 16000000UL // 16 MHz
#endif
#include <avr/io.h>
#include <avr/interrupt.h>
#include <util/delay.h>

#define TX_PIN  PB0

volatile uint16_t tx_shift_reg = 0;

ISR(TIMER0_COMPA_vect) {
   uint16_t local_tx_shift_reg = tx_shift_reg;
   if( local_tx_shift_reg & 0x01 ) {
      PORTB |= _BV(TX_PIN);
   } else {
      PORTB &= ~_BV(TX_PIN);
   }
   local_tx_shift_reg >>= 1;
   if(!local_tx_shift_reg) {
      // Stop timer0.
      GTCCR |= (1<<TSM) | (1<<PSR0);
   }
   tx_shift_reg = local_tx_shift_reg;
}

void UART_tx(char byte) {
   uint16_t local_tx_shift_reg = tx_shift_reg;
   local_tx_shift_reg = (0b1<<9) | ((uint16_t)byte<<1);
   tx_shift_reg = local_tx_shift_reg;
   TCNT0 = 0;
   TCCR0B |= (1<<CS02)|(1<<CS00); // 1024 prescaler
   GTCCR &= ~(1<<TSM);
}

void UART_tx_char(char c) {
   UART_tx( c );
   // wait until transmission is finished
   while(tx_shift_reg);
}

void UART_init() {
   cli()
   // set TX pins as output
   DDRB |= (1<<TX_PIN);
   PORTB |= (1<<TX_PIN);
   // set timer0 to CTC mode, keep it halted.
   TCCR0A |= (1<<WGM01);
   TCCR0B = 0;
   // enable interrupt
   TIMSK |= (1<<OCIE0A);
   OCR0A = 128;
   OCR0B = 128;
   TCNT0 = 0;
   GTCCR |= (1<<TSM);
   sei();
}

void main(void)
{
   UART_init();
   while(1) {
      for(char c = 1; c < 128; ++c) {
         UART_tx_char(c);
         _delay_ms(100);
      }
   }
}

Затем arduino получает биты: 

/*
 * ATtiny85 bit-bang uart monitor for ATmega32u4
 */
#define LED_PIN 13
#define RX_PIN 7
// rx_state == 0 // timer1 not running
// rx_state == 1 // receive in progress
// rx_state == 2 // data ready in rx_data_reg
volatile int rx_state = 0;
volatile int rx_bit_nro = 0;
volatile uint16_t rx_shift_reg = 0;
volatile uint16_t rx_data_reg = 0;

void rx_start_interupt() {
  if(rx_state == 0) {
    digitalWrite(LED_PIN, HIGH);
    while(digitalRead(RX_PIN));
    // Start timer1
    rx_state++;
    TCNT1  = 0;
    TCCR1B = (1 << WGM12) | (1 <<CS12) | (1 << CS10);
  }
}

ISR(TIMER1_COMPA_vect) {
  uint16_t bit = digitalRead(RX_PIN) > 0;
  rx_shift_reg >>= 1;
  rx_shift_reg |= (bit << 7);
  ++rx_bit_nro;
  if(rx_bit_nro == 9) {
    // Stop timer.
    TCCR1B = 0;
    TCNT1  = 0;
    rx_data_reg = rx_shift_reg;
    rx_shift_reg = 0;
    rx_bit_nro = 0;
    rx_state++;
    digitalWrite(LED_PIN, LOW);
  }
}

void setup() {
  noInterrupts();
  // Program timer1 for UART bit bang receive.
  TCCR1A = 0; // set entire TCCR1A register to 0 (stops it)
  TCCR1B = 0; // same for TCCR1B
  TCNT1  = 0; // initialize counter value to 0
  OCR1A = 128;
  TIMSK1 |= (1 << OCIE1A);
  interrupts();

  pinMode(LED_PIN, OUTPUT);
  pinMode(RX_PIN, INPUT);

  // Attach RX start interupt.
  pinMode(digitalPinToInterrupt(RX_PIN), INPUT);
  attachInterrupt(digitalPinToInterrupt(RX_PIN), rx_start_interupt, FALLING);

  Serial.begin(9600);
  while(!Serial);
  Serial.print("F_CPU:");
  Serial.println(F_CPU,DEC);
  Serial.println("Waiting for data from attiny85...");
}

void loop() {
  if(rx_state == 2) {
    uint16_t local_rx_data = rx_data_reg;
    rx_state = 0;
    Serial.println(local_rx_data,HEX);
  }
}

Я перепробовал почти все, чтобы все заработало, но полученные байты возвращаются. Чего мне не хватает?

Примечание: я использую timer0 на attiny85 и timer1 на arduino. Решено: переключение ISR на TIMER1_COMPAB_vect и OCR1B = 64 на самом деле работает! Ура!

...