Преобразование выражения с >> = для обозначения - PullRequest
Новая
       73

Преобразование выражения с >> = для обозначения

1 голос
/ 19 марта 2020

У меня есть следующий код 

newtype State s a = State { runState :: s -> (s,a) }    
evalState :: State s a -> s -> a
evalState sa s = snd $ runState sa s

instance Functor (State s) where
  fmap f sa = State $ \s ->
    let (s',a) = runState sa s in
      (s',f a)

instance Applicative (State s) where
  pure a = State $ \s -> (s,a)

  sf <*> sa = State $ \s ->
    let (s',f) = runState sf s
        (s'',a) = runState sa s' in
      (s'', f a)

instance Monad (State s) where
  sa >>= k = State $ \s ->
    let (s',a) = runState sa s in
      runState (k a) s'

get :: State s s
get = State $ \s -> (s,s)

set :: s -> State s ()
set s = State $ \_ -> (s,())

bar (acc,n) = if n <= 0
              then return ()
              else
              set (n*acc,n-1)

f x = factLoop

factLoop =  get >>= bar >>= f

И 

 runState factLoop (1,7)

дает ((5040,0),())

Я пытаюсь написать функцию 

 factLoop =  get >>= bar >>= f

используя нотацию do

Я пытался 

 factLoop' =  do
                (x,y) <- get 
                h <-  bar (x,y) 
                return ( f h)

Но это не дает правильного типа, который должен быть State (Int, Int) ()

Есть идеи?

Спасибо!

Ответы [ 2 ]

8 голосов
/ 19 марта 2020

Просто удалите return в последней строке: 

factLoop' =  do
                (x,y) <- get 
                h <-  bar (x,y) 
                f h

В исходном коде нет return, поэтому в версии нотации do также не должно быть ни одного. do нотация просто "переводит" использование >>=, как вы уже сделали.

1 голос
/ 19 марта 2020

>>= это infixl 1 (бинарный оператор слева), так что у вас действительно есть 

f x = factLoop

factLoop =  get >>= bar >>= f
         =  (get >>= bar) >>= f
         =  (get >>= bar) >>= (\x -> f x)
         = do { x <- (get >>= bar)
              ; f x }
         = do { _ <- (get >>= bar)
              ; factLoop }
         = do { _ <- (get >>= (\x -> bar x))
              ; factLoop }
         = do { _ <- do { x <- get 
                        ; bar x }
              ; factLoop }
         = do { x <- get 
              ; _ <- bar x 
              ; factLoop }

последний из-за закона ассоциативности монады ( «Композиция Клейсли образует категорию» ).

Делая это принципиально, вам не нужно угадывать. Через некоторое время вы, конечно, почувствуете это, но пока вы не почувствуете формальность, это поможет.

...