SUMIFS с критериями множественного ИЛИ / И (используя ссылку на ячейку)

Question

      A             B              C            D               E            F          G        E
1  Products     Suppliers        Value     Criteria 1:     Product_C      Result:      600
2  Product_A    Supplier_01      500       Criteria 2:     Supplier_01      
3  Product_B    Supplier_01      600       Criteria 3:     Supplier_03  
4  Product_B    Supplier_02      300                
5  Product_C    Supplier_01      200                
6  Product_C    Supplier_01      400                
7  Product_C    Supplier_03      800    
8
9

В таблице вы найдете список различных Products (Column A) и Suppliers (Column B).

В Cell G1 Я хочу получить sum значений в Column C, если выполняются следующие условия:

Продукт = Product_C И
Поставщик = Supplier_01 ИЛИ Supplier_03

Эти условия вводятся как Criteria 1-3 в Cells E1:E3.

Чтобы добиться этого, я попытался go с решением этих вопросов ( Q1 , Q2 ), который дает мне правильный результат:

G1 =SUM(SUMIFS($C:$C,$A:$A,$E$1,$B:$B,{"Supplier_01","Supplier_02"}))

---

Однако моя проблема с этим решением заключается в том, что мне нужно ввести OR-criterias вручную как {"Supplier_01","Supplier_02"}.
Как мне изменить мою формулу, чтобы я мог ссылаться на значения в Cells E2:E3, чтобы, если пользователь изменяет эти значения, результат автоматически корректировался?

Answer 1

Я собирался сказать, что вам нужно транспонировать E2: E3. Я думаю, что это в целом верно, но в данном конкретном случае, когда к столбцу А применяется только один критерий, вам не нужно:

=SUM(SUMIFS($C:$C,$A:$A,$E$1,$B:$B,$E$2:$E$3))

работает, если введено как формула массива.

Если у вас есть несколько критериев для A и B, вам нужно транспонировать один набор критериев:

=SUM(SUMIFS($C:$C,$A:$A,$E$1:$E$2,$B:$B,TRANSPOSE($E$3:$E$4)))

Answer 2

Одна возможность:

=SUMPRODUCT((A2:A7=E1)*((B2:B7=E2)+(B2:B7=E3))*C2:C7)

Будет легко расширить критерии одинаково для столбцов A и B.

Answer 3

попробуйте

=SUM(SUMIFS($C:$C,$A:$A,$E$1,$B:$B,E2:E3))

или

=SUM(IF(($A$2:$A$7=E1)*(($B$2:$B$7=E2)+($B$2:$B$7=E3)),$C$2:$C$7,0))