Как я уже сказал в комментарии, вы можете обработать текстовый файл с помощью unparsed-text и tokenize, чтобы преобразовать его в XML (или использовать unparsed-text-lines и tokenize в XSLT 3, если доступно), затем остальные задачи могут быть выполнены с помощью вложенных xsl:for-each-group s, возможно, даже с одной или двумя рекурсивными функциями после того, как установлен регулярный шаблон; следующее пытается разобрать вложенные for-each-group s:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
expand-text="yes"
xmlns:mf="http://example.com/mf"
exclude-result-prefixes="#all"
version="3.0">
<xsl:param name="data" as="xs:string">01,TeacherHeader1
02,StudentHeader1
03,SubjectHeader1
10,Grade1,Score99
10,Grade2,Score99
48,SubjectTrailer1
49,StudentTrailer1
02,StudentHeader2
03,SubjectHeader1
10,Grade1,Score50
10,Grade2,Score50
48,SubjectTrailer1
49,StudentTrailer2
50,TeacherTrailer1</xsl:param>
<xsl:param name="header-ids" as="xs:string*"
select="'01', '02', '03', '10', '48', '49', '50'"/>
<xsl:param name="header-names" as="xs:string*"
select="'FileHeader ', 'GroupHeader', 'AccountHeader', 'Details', 'AccountTrailer', 'GroupTrailer', 'FileTrailer'"/>
<xsl:variable name="lines">
<xsl:for-each select="tokenize($data, '\r?\n')">
<line>
<xsl:variable name="tokens" as="xs:string*" select="tokenize(., ',')"/>
<id>{$tokens[1]}</id>
<name>{$tokens[2]}</name>
<xsl:if test="$tokens[3]">
<value>{$tokens[3]}</value>
</xsl:if>
</line>
</xsl:for-each>
</xsl:variable>
<xsl:mode on-no-match="shallow-copy"/>
<xsl:output method="xml" indent="yes"/>
<xsl:template match="/" name="xsl:initial-template">
<xsl:for-each-group select="$lines/line" group-starting-with="line[id = '01']">
<File>
<xsl:apply-templates select="."/>
<xsl:for-each-group select="current-group() except ." group-ending-with="line[id = '50']">
<xsl:for-each-group select="current-group()[position() lt last()]" group-starting-with="line[id = '02']">
<GroupRecord>
<xsl:apply-templates select="."/>
<xsl:for-each-group select="current-group() except ." group-ending-with="line[id = '49']">
<xsl:for-each-group select="current-group()[position() lt last()]" group-starting-with="line[id = '03']">
<AccountRecord>
<xsl:apply-templates select="."/>
<AccountDetails>
<xsl:apply-templates select="(current-group() except .)[id != '48']"/>
</AccountDetails>
<xsl:apply-templates select="current-group()[id = '48']"/>
</AccountRecord>
</xsl:for-each-group>
<xsl:apply-templates select="current-group()[last()]"/>
</xsl:for-each-group>
</GroupRecord>
</xsl:for-each-group>
<xsl:apply-templates select="current-group()[last()]"/>
</xsl:for-each-group>
</File>
</xsl:for-each-group>
</xsl:template>
<xsl:template match="line">
<xsl:element name="{$header-names[index-of($header-ids, current()/id)]}">
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
</xsl:stylesheet>
https://xsltfiddle.liberty-development.net/gWEaSv8. Образцы данных были встроены для полноты и компактности примера, но вы, конечно, могли бы использовать <xsl:param name="data" as="xs:string" select="unparsed-text('file.txt')"/> вместо этого. Я также использовал декларацию xsl:mode и name="xsl:initial-template", обе функции XSLT 3, которые вам нужно будет адаптировать для процессора XSLT 2, чтобы описать преобразование идентичности и использовать другое имя шаблона, например, name="main", в качестве записи указать код. Я также использовал там шаблон текстовых значений, такой как <id>{$tokens[1]}</id>, для процессора XSLT 2 вам нужно будет использовать, например, <id><xsl:value-of select="$tokens[1]"/</id>.