PRO C MEANS - сохранить таблицу, показанную в результатах, а не в выходных данных

Question

У меня есть следующий код для создания описательной статистики:

proc means data=sashelp.cars;
    var Horsepower Weight Length;
    output out =  cars_stats mean = std = /autoname;
run;

Я хотел бы получить таблицу, показанную на вкладке «Результаты» в «Выходных данных», так как позже я экспортирую таблицы в Excel.

В настоящий момент я получаю следующее:

Но я получаю это на вкладке Выходные данные.

Как получить таблицу из результатов в выходных данных?

Answer 1

ods на помощь!

Сначала запустите ваш код следующим образом:

ods trace on;
proc means data=sashelp.class;
    var Weight Height;
    output out =  class_stats mean = std = /autoname;
run;
ods trace off;

Затем проверьте журнал:

Output Added:
-------------
Name:       Summary <-- We want this bit
Label:      Summary statistics
Template:   base.summary
Path:       Means.Summary
-------------

Затем перезапустите например:

ods select none;
ods output summary = class_summary;
proc means data=sashelp.class;
    var Weight Height;
    output out =  class_stats mean = std = /autoname;
run;
ods select all;

Этот подход позволяет вам захватывать любые выходные данные любого про c, которые обычно вместо этого отображаются в области результатов в виде набора данных sas.

Answer 2

Proc MEANS с опцией STACKODSOUTPUT создаст ту же желаемую таблицу.

ods select none;
proc means data=sashelp.cars stackodsoutput;
    var Horsepower Weight Length;
    ods output summary = cars_stats_stacked;
run;
ods select all;