Найти все дубликаты в столбце определенного значения и вернуть значения из следующего столбца

Question

Я пытаюсь сделать что-то похожее на это:

В таблице справа будут все уникальные записи, которые будет храниться в определенной области. Однако некоторые записи могут существовать в большем количестве областей, и эта информация может быть взята из списка в столбцах A и B. Макрос должен брать каждую уникальную запись в столбце D и искать ее в столбце A, каждый раз, когда он ее находит, следует скопируйте местоположение / область в столбце B и вставьте рядом с уникальной записью в таблице. Я думаю, что я мог бы сделать это с помощью al oop, но то, что я создал в приведенном ниже коде, на самом деле не работает.

Вторая задача состоит в том, чтобы понять, что в месте, скопированном в таблицу, новое найденное место необходимо вставить в следующую свободную ячейку той же уникальной записи.

Я знаю, что мой код немного пугает, но я был бы признателен даже за совет, в каком направлении я должен искать ... Заранее спасибо!

Sub searcharea()

    Dim UC As Variant, UCrng As Range, ra As Range

    Set UCrng = Range("F2:F6")

    For Each UC In UCrng

        Set ra = Cells.Find(What:=UC, LookIn:=xlFormulas, _
        LookAt:=xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlNext, _
        MatchCase:=False, SearchFormat:=False).Activate

        ra.Offset(0, 1).Copy Destination:=Range("E2")

    Next

End Sub

Answer 1

Попробуйте:

Option Explicit

Sub test()

    Dim LastRowA As Long, LastRowD As Long, i As Long, rngColumn As Long
    Dim rng As Range

    With ThisWorkbook.Worksheets("Sheet1")

        LastRowD = .Cells(.Rows.Count, "D").End(xlUp).Row

        .Range("D2:J" & LastRowD).ClearContents

        LastRowA = .Cells(.Rows.Count, "A").End(xlUp).Row

        For i = 2 To LastRowA

            LastRowD = .Cells(.Rows.Count, "D").End(xlUp).Row

            Set rng = .Range("D1:D" & LastRowD).Find(.Range("A" & i).Value, LookIn:=xlValues, lookat:=xlWhole)

            If Not rng Is Nothing Then
                rngColumn = .Cells(rng.Row, .Columns.Count).End(xlToLeft).Column
                Cells(rng.Row, rngColumn + 1).Value = .Range("B" & i).Value
            Else
                .Range("D" & LastRowD + 1).Value = .Range("A" & i).Value
                .Range("E" & LastRowD + 1).Value = .Range("B" & i).Value
            End If

        Next i

    End With

End Sub

Answer 2

Я думаю, этот код будет делать то, что вы хотите. Пожалуйста, попробуйте.

Option Explicit

Sub SortToColumns()
    ' Variatus @STO 30 Jan 2020

    Dim WsS As Worksheet                    ' Source
    Dim WsT As Worksheet                    ' Target
    Dim Rng As Range
    Dim Fn As String, An As String          ' File name, Area name
    Dim Rls As Long
    Dim Rs As Long
    Dim Rt As Long, Ct As Long

    With ThisWorkbook                       ' change as required
        Set WsS = .Worksheets("Sheet1")     ' change as required
        Set WsT = .Worksheets("Sheet2")     ' change as required
    End With

    With WsT
        ' delete all but the caption row
        .Range(.Cells(2, 1), .Cells(.Rows.Count, "A").End(xlUp)).EntireRow.ClearContents
    End With

    Application.ScreenUpdating = False
    With WsS
        ' find last row of source data
        Rls = .Cells(.Rows.Count, "A").End(xlUp).Row

        For Rs = 2 To Rls                   ' start from row 2 (row 1 is caption)
            Fn = .Cells(Rs, "A").Value
            An = .Cells(Rs, "B").Value
            If FileNameRow(Fn, WsT, Rt) Then
                ' add to existing item
                With WsT
                    Ct = .Cells(Rt, .Columns.Count).End(xlToLeft).Column
                    Set Rng = .Range(.Cells(Rt, "B"), .Cells(Rt, Ct))
                End With
                With Rng
                    Set Rng = .Find(An, .Cells(.Cells.Count), xlValues, xlWhole, xlByRows, xlNext)
                End With
                ' skip if Area exists
                If Rng Is Nothing Then WsT.Cells(Rt, Ct + 1).Value = An
            Else
                ' is new item
                WsT.Cells(Rt, "A").Value = Fn
                WsT.Cells(Rt, "B").Value = An
            End If
        Next Rs
    End With
    Application.ScreenUpdating = True
End Sub

Private Function FileNameRow(Fn As String, _
                             WsT As Worksheet, _
                             Rt As Long) As Boolean
    ' Rt is a return Long
    ' return True if item exists (found)

    Dim Fnd As Range
    Dim Rng As Range
    Dim R As Long

    With WsT
        R = .Cells(.Rows.Count, "A").End(xlUp).Row
        Set Rng = .Range(.Cells(2, "A"), .Cells(R, "A"))
        Set Fnd = Rng.Find(Fn, Rng.Cells(Rng.Cells.Count), xlValues, xlWhole, xlByRows, xlNext)

        If Fnd Is Nothing Then
            Rt = Application.Max(.Cells(.Rows.Count, "A").End(xlUp).Row + 1, 2)
        Else
            Rt = Fnd.Row
            FileNameRow = True
        End If
    End With
End Function

Answer 3

Я бы предложил пройти по всем строкам (столбцы A + B), например:

For i = 1 to Rows.Count
'DoStuff
Next i

Для каждой строки вы копируете значение A в D, если его там еще нет. Вы можете получить доступ к таким значениям, как это:

Cells(i, "A").Value
Cells(i, "B").Value

Чтобы найти значения в столбце, см. Здесь . Если вы нашли дубликат, используйте другой l oop, чтобы проверить, какой столбец (E, F, G, ..) в указанной вами строке c является первым пустым и после значения столбца B там.