Получить адрес электронной почты от идентификатора emloyee, хранящегося в Excel

Question

Мне нужно получить адрес электронной почты на основе идентификатора сотрудника.

Я копирую идентификаторы сотрудников из Excel и вставляю их в поле «Кому» почты Outlook.

Я не могу нажать Ctrl + K, используя код макроса.

Я использую приведенный ниже код для вставки идентификаторов сотрудников в приложении Outlook.

Sub Combinedata()

    Dim i As Integer
    Dim count As Integer
    Dim s As String
    Dim outRec As Object

    count = Cells(Rows.count, "A").End(xlUp).Row
    For i = 1 To count
        s = s & Cells(i, 1) & ";"
    Next
    'Range("D2") = s

    Set OutApp = CreateObject("Outlook.Application")

    On Error GoTo 0    
    Set OutMail = OutApp.CreateItem(0)
    On Error Resume Next
    With OutMail                   
        .To = s                  
        .Display                                    
    End With
    On Error GoTo 0
    Set OutMail = Nothing

End Sub

Answer 1

.Recipients.ResolveAll копия ctrl + K.

Option Explicit ' Consider this mandatory
' Tools | Options | Editor tab
' Require Variable Declaration
'
' If desperate declare as variant

Sub Combinedata()

Dim i As Long
Dim count As Long

Dim s As String

Dim OutApp As Object
Dim outMail As Object

count = Cells(Rows.count, "A").End(xlUp).Row
For i = 1 To count
    s = s & Cells(i, 1) & ";"
Next

Set OutApp = CreateObject("Outlook.Application")
Set outMail = OutApp.CreateItem(0)

With outMail
    .To = s
    .Recipients.ResolveAll
    .Display
End With

End Sub