Сделайте так, чтобы файл выглядел не перепутанным - PullRequest
Новая
       28

Сделайте так, чтобы файл выглядел не перепутанным

0 голосов
/ 25 февраля 2020

У меня есть файл, который выглядит испорченным: 

contig_1  bin.0013 Rhizobium           flavum    (taxid 1335061)
contig_2           Alphaproteobacteria (taxid    28211)
contig_3  bin.009
contig_4  bin.008  unclassified        (taxid    0)
contig_5  bin.001  Fluviicoccus        keumensis (taxid 1435465)
contig_12 bin.003

Я хочу, чтобы он выглядел правильно с разделенными табуляцией столбцами и нулями, где он пуст: 

contig_1    bin.0013    Rhizobium flavum (taxid 1335061)
contig_2    0           Alphaproteobacteria (taxid 28211)
contig_3    bin.009     0
contig_4    bin.008     unclassified (taxid 0)
contig_5    bin.001     Fluviicoccus keumensis (taxid 1435465)
contig_12   bin.003     0

Если я использую что-то как sed 's/ /,/g' filename запятые вставляются везде, кроме 1-2 и 2-3 столбцов.

1 Ответ

1 голос
/ 26 февраля 2020

Если awk - ваш вариант, попробуйте следующее: 

awk -v OFS="\t" '
NR==FNR {
    # in the 1st pass, detect the starting positions of the 2nd field and the 3rd
    sub(" +$", "")      # it avoids misdetection due to extra trailing blanks
    if (match($0, "[^[:blank:]]+[[:blank:]]+")) {
        # RLENGTH holds the ending position of the 1st blank
        if (col2 == 0 || RLENGTH < col2) col2 = RLENGTH + 1
        if (match($0, "[^[:blank:]]+[[:blank:]]+[^[:blank:]]+[[:blank:]]+")) {
            # RLENGTH holds the ending position of the 2nd blank
            if (col3 == 0 || RLENGTH < col3) col3 = RLENGTH + 1
        }
    }
    next
}
{
    # in the 2nd pass, extract the substrings in the fixed position and reformat them
    # by removing extra spaces and putting "0" if the fiels is empty
    c1 = substr($0, 1, col2 - 1); sub(" +$", "", c1); if (c1 == "") c1 = "0"
    c2 = substr($0, col2, col3 - col2); sub(" +$", "", c2); if (c2 == "") c2 = "0"
    c3 = substr($0, col3); gsub(" +", " ", c3); if (c3 == "") c3 = "0"
#   print c1, c2, c3            # use this for the tab-separated output
    printf("%-12s%-12s%-s\n", c1, c2, c3)
}' file file

Вывод: 

contig_1    bin.0013    Rhizobium flavum (taxid 1335061)
contig_2    0           Alphaproteobacteria (taxid 28211)
contig_3    bin.009     0
contig_4    bin.008     unclassified (taxid 0)
contig_5    bin.001     Fluviicoccus keumensis (taxid 1435465)
contig_12   bin.003     0
  • Процесс состоит из двух проходов. На 1-м проходе он определяет начальные позиции полей.
  • На 2-м проходе он вырезает отдельные поля, используя позиции, рассчитанные на 1-м проходе.
  • Я выбрал printf, чтобы визуально выровнять вывод. Вы можете переключиться на tab separated values в зависимости от предпочтений.
...