Как запустить VBScript в 32-битном режиме на 64-битной машине?

Question

У меня есть текстовый файл с расширением .vbs, в котором я написал следующее:

Set Conn = CreateObject("ADODB.Connection")
Conn.Provider = "Microsoft.ACE.OLEDB.12.0"
Conn.Properties("Data Source") = "C:\dummy.accdb"
Conn.Properties("Jet OLEDB:Database Password") = "pass"
Conn.Open
Conn.Close
Set Conn = Nothing

• Когда я выполняю это на 32-битной машине с Windows, она запускается и заканчивается без каких-либо предположений (ожидается).
• Когда я выполняю это на 64-битной машине с Windows, появляется ошибка

  Провайдер не найден. Возможно, он неправильно установлен.

Но оно установлено. Я думаю, корень проблемы в том, что провайдер является 32-битным, насколько я знаю, он не существует как 64-битный.

Если я запускаю VBScript через IIS на моей 64-битной машине (как файл ASP), я могу выбрать, что он должен работать в 32-битном режиме. Затем он может найти поставщика.

Как я могу найти провайдера в Windows 64-bit? Могу ли я как-то сказать CScript (который выполняет текстовый файл .vbs) для работы в 32-битном режиме?

Answer 1

следовать http://support.microsoft.com/kb/896456

Чтобы запустить 32-разрядную командную строку, выполните следующие действия:

* Click Start, click Run, type %windir%\SysWoW64\cmd.exe, and then click OK.

Затем введите

cscript vbscriptfile.vbs

Answer 2

' C:\Windows\System32\WScript.exe = WScript.exe
Dim ScriptHost : ScriptHost = Mid(WScript.FullName, InStrRev(WScript.FullName, "\") + 1, Len(WScript.FullName))

Dim oWs : Set oWs = CreateObject("WScript.Shell")
Dim oProcEnv : Set oProcEnv = oWs.Environment("Process")

' Am I running 64-bit version of WScript.exe/Cscript.exe? So, call script again in x86 script host and then exit.
If InStr(LCase(WScript.FullName), LCase(oProcEnv("windir") & "\System32\")) And oProcEnv("PROCESSOR_ARCHITECTURE") = "AMD64" Then
    ' rebuild arguments
    If Not WScript.Arguments.Count = 0 Then
        Dim sArg, Arg
        sArg = ""
        For Each Arg In Wscript.Arguments
              sArg = sArg & " " & """" & Arg & """"
        Next
    End If

    Dim sCmd : sCmd = """" &  oProcEnv("windir") & "\SysWOW64\" & ScriptHost & """" & " """ & WScript.ScriptFullName & """" & sArg
    WScript.Echo "Call " & sCmd
    oWs.Run sCmd
    WScript.Quit
End If

Answer 3

Если вы контролируете запуск исполняемого файла cscript, запустите версию X:\windows\syswow64\cscript.exe, которая является 32-битной реализацией.

Answer 4

Мы можем заставить vbscript всегда запускаться в 32-битном режиме, изменив «system32» на «sysWOW64» в значении по умолчанию ключа «Computer \ HKLM \ SOFTWARE] \ Classes \ VBSFile \ Shell \ Open \ Command»

Answer 5

   ' ***************
   ' *** 64bit check
   ' ***************
   ' check to see if we are on 64bit OS -> re-run this script with 32bit cscript
   Function RestartWithCScript32(extraargs)
   Dim strCMD, iCount
   strCMD = r32wShell.ExpandEnvironmentStrings("%SYSTEMROOT%") & "\SysWOW64\cscript.exe"
   If NOT r32fso.FileExists(strCMD) Then strCMD = "cscript.exe" ' This may not work if we can't find the SysWOW64 Version
   strCMD = strCMD & Chr(32) & Wscript.ScriptFullName & Chr(32)
   If Wscript.Arguments.Count > 0 Then
    For iCount = 0 To WScript.Arguments.Count - 1
     if Instr(Wscript.Arguments(iCount), " ") = 0 Then ' add unspaced args
      strCMD = strCMD & " " & Wscript.Arguments(iCount) & " "
     Else
      If Instr("/-\", Left(Wscript.Arguments(iCount), 1)) > 0 Then ' quote spaced args
       If InStr(WScript.Arguments(iCount),"=") > 0 Then
        strCMD = strCMD & " " & Left(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), "=") ) & """" & Mid(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), "=") + 1) & """ "
       ElseIf Instr(WScript.Arguments(iCount),":") > 0 Then
        strCMD = strCMD & " " & Left(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), ":") ) & """" & Mid(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), ":") + 1) & """ "
       Else
        strCMD = strCMD & " """ & Wscript.Arguments(iCount) & """ "
       End If
      Else
       strCMD = strCMD & " """ & Wscript.Arguments(iCount) & """ "
      End If
     End If
    Next
   End If
   r32wShell.Run strCMD & " " & extraargs, 0, False
   End Function

   Dim r32wShell, r32env1, r32env2, r32iCount
   Dim r32fso
   SET r32fso = CreateObject("Scripting.FileSystemObject")
   Set r32wShell = WScript.CreateObject("WScript.Shell")
   r32env1 = r32wShell.ExpandEnvironmentStrings("%PROCESSOR_ARCHITECTURE%")
   If r32env1 <> "x86" Then ' not running in x86 mode
    For r32iCount = 0 To WScript.Arguments.Count - 1
     r32env2 = r32env2 & WScript.Arguments(r32iCount) & VbCrLf
    Next
    If InStr(r32env2,"restart32") = 0 Then RestartWithCScript32 "restart32" Else MsgBox "Cannot find 32bit version of cscript.exe or unknown OS type " & r32env1
    Set r32wShell = Nothing
    WScript.Quit
   End If
   Set r32wShell = Nothing
   Set r32fso = Nothing
   ' *******************
   ' *** END 64bit check
   ' *******************

Поместите приведенный выше код в начало вашего скрипта, и последующий код будет работать в 32-битном режиме с доступом к 32-битным драйверам ODBC. Источник .

Answer 6

В сценарии запуска вы можете принудительно запустить его, он позволяет сохранить один и тот же сценарий и один и тот же модуль запуска для обеих архитектур

:: For 32 bits architecture, this line is sufficent (32bits is the only cscript available)
set CSCRIPT="cscript.exe"
:: Detect windows 64bits and use the expected cscript (SysWOW64 contains 32bits executable)
if exist "C:\Windows\SysWOW64\cscript.exe" set CSCRIPT="C:\Windows\SysWOW64\cscript.exe"
%CSCRIPT% yourscript.vbs

Answer 7

Альтернативный метод для запуска 32-битных скриптов на 64-битной машине: % windir% \ syswow64 \ cscript.exe vbscriptfile.vbs