Как разделить xml String при использовании XSLT1.0?

Question

Это мой Xml файл. Я хочу разделить месяц на другой, год на другой и 000 / xxx как другой Как мы можем сделать это в XSLT1.0 ??

МОЙ xml Код: -

<COMBINED-PAYMENT-HISTORY>January:2019,000/XXX|February:2018,000/XXX|
  </COMBINED-PAYMENT-HISTORY>

Ожидаемый результат: -

      <table>
    <tr>
        <td>January</td>

    </tr>
    <tr>
        <td class="AccValue1">2019</td>
        <td class="AccValue1">000/XXX</td>

    </tr>
    <tr>
        <td>February</td>

    </tr>
    <tr>
        <td class="AccValue1">2018</td>
        <td class="AccValue1">000/XXX</td>

    </tr>
</table>

Answer 1

Вот как вы можете проанализировать ввод в таблицу HTML. Обратите внимание, что это может быть проще, если бы каждый элемент был строкой, а не столбцом.

XSLT 1.0 (+ набор узлов EXSLT)

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="COMBINED-PAYMENT-HISTORY">
    <xsl:variable name="items-rtf">
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="normalize-space(.)"/>
        </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="items" select="exsl:node-set($items-rtf)/item" />
    <table>
        <!-- month -->
        <tr>
            <xsl:for-each select="$items">
                <td>
                    <xsl:value-of select="substring-before(., ':')" />
                </td>
            </xsl:for-each>
        </tr>
        <!-- year -->
        <tr>
            <xsl:for-each select="$items">
                <td>
                    <xsl:value-of select="substring-before(substring-after(., ':'), ',')" />
                </td>
            </xsl:for-each>
        </tr>
        <!-- data -->
        <tr>
            <xsl:for-each select="$items">
                <td>
                    <xsl:value-of select="substring-after(., ',')" />
                </td>
            </xsl:for-each>
        </tr>
    </table>    
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="'|'"/>
        <xsl:variable name="token" select="substring-before($text, $delimiter)" />
        <item>
            <xsl:value-of select="$token"/>
        </item>
        <xsl:variable name="next" select="substring-after($text, $delimiter)"/>
        <xsl:if test="$next">
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="$next"/>
            </xsl:call-template>
        </xsl:if>
</xsl:template>

</xsl:stylesheet>

Результат

<?xml version="1.0" encoding="UTF-8"?>
<table>
  <tr>
    <td>Mar</td>
    <td> Mar</td>
  </tr>
  <tr>
    <td>2019</td>
    <td>2018</td>
  </tr>
  <tr>
    <td>000/XXX</td>
    <td>000/XXX</td>
  </tr>
</table>

Оказано: