Как установить точку останова в необходимом модуле из файла инициализации .perldb?

Question

Последующий вопрос к Установить точку останова из файла инициализации .perldb . Я пытаюсь установить точку останова в модуле, который загружается во время выполнения. Для целей тестирования я создал следующие файлы:

/home/hakon/test/perl/perldb/p.pl:

use feature qw(say);
use strict;
use warnings;
use lib "./lib";

say "Line 6";
say "Line 7";
require My::Module;
say "Line 9";

/home/hakon/test/perl/perldb/lib/My/Module.pm

package My::Module;
use feature qw(say);
use strict;
use warnings;

say "MM Line 6";
say "MM Line 7";
say "MM Line 8";

1;

/home/hakon/test/perl/perldb/.perldb

sub afterinit {
    push @DB::typeahead,
      "b p.pl:8",
      "c",
      "b /home/hakon/test/perl/perldb/lib/My/Module.pm:7",
      "c"
      ;
}

Когда я запускаю скрипт с отладчиком, я получаю:

$ perl -d p.pl

Loading DB routines from perl5db.pl version 1.55
Editor support available.

Enter h or 'h h' for help, or 'man perldebug' for more help.

main::(p.pl:6): say "Line 6";
auto(-4)  DB<1> b p.pl:8
auto(-3)  DB<2> c
Line 6
Line 7
main::(p.pl:8): require My::Module;
auto(-2)  DB<2> b /home/hakon/test/perl/perldb/lib/My/Module.pm:7
auto(-1)  DB<3> c
MM Line 6
MM Line 7
MM Line 8
Line 9
Debugged program terminated.  Use q to quit or R to restart,
use o inhibit_exit to avoid stopping after program termination,
h q, h R or h o to get additional info.

Таким образом, точка останова в строке 7 Module.pm игнорируется. Как я могу остановить отладчик в точке останова?

Answer 1

Кажется, что невозможно установить точку останова в требуемом модуле до его компиляции, но можно обойти проблему, сначала используя команду b load filename, а затем задав точку останова. с тех пор требуемый модуль уже будет скомпилирован:

sub afterinit {
    push @DB::typeahead,
      "b p.pl:8",
      "c",
      "b load lib/My/Module.pm",
      "c",
      "b lib/My/Module.pm:7",
      "c"
      ;
}

Это работает для меня.

Примечание:

Если бы я использовал

use FindBin qw/$Bin/;
use lib "$Bin/lib";

вместо

use lib './lib';

в скрипте p.pl, я должен был бы использовать абсолютные пути с командой b вместо относительных путей:

sub afterinit {
    push @DB::typeahead,
      "b p.pl:8",
      "c",
      "b load /home/hakon/test/perl/perldb/lib/My/Module.pm",
      "c",
      "b /home/hakon/test/perl/perldb/lib/My/Module.pm:7",
      "c"
      ;
}