Пакетный файл: разбирать строку после появления подстроки, а не разделителя - PullRequest
Новая
       108

Пакетный файл: разбирать строку после появления подстроки, а не разделителя

0 голосов
/ 04 мая 2020

У меня есть и сценарий пакетного файла показывает мне вывод утилиты adb. 

FOR /F "skip=1 delims=~" %%x IN ('adb devices -l') DO echo %%x

2 строки вывода 

0123456789ABCDEF       device product:java_joyplus_qb7 model:TM702B4_3G device:java_joyplus_qb7 transport_id:12
F9NPFP084096           device product:WW_P023 model:P023 device:P023_1 transport_id:11

Я хочу разобрать непустую подстроку после "transport_id:". Для первой строки я хочу получить 12, для второй 11. Как я могу это сделать?

Ответы [ 3 ]

2 голосов
/ 04 мая 2020

Если я правильно понимаю, что вы спросили, следующий должен вывести необходимую вам информацию. 

@Echo Off

For /F "Skip=1 Tokens=1*" %%G In ('adb.exe devices -l') Do (Set "DI=%%H"
    SetLocal EnableDelayedExpansion
    For /F %%I In ("!DI:*transport_id:=!") Do EndLocal & Echo %%I)

Pause

И, если вы хотите сделать это из : 

For /F "Skip=1Tokens=1*" %G In ('adb.exe devices -l')Do @Set "DI=%H"&For /F %I In ('Cmd /D/V/C Echo "!DI:*transport_id:=!"')Do @Echo %~I
1 голос
/ 04 мая 2020 
SETLOCAL EnableDelayedExpansion
REM … 
FOR /F "skip=1 delims=~" %%x IN ('adb devices -l') DO (
    set "_ID="&set "_transport_id="
    call :parse "" "%%~x"
    echo transport_id !_transport_id!  (!_ID!^)
)

REM … remaining part of your script here …

goto :eof

:parse
if "%~2"=="" goto :eof 
for /F "tokens=1,*" %%G in ("%~2") do (
  if "%~1"=="" (
    set "_ID=%%~G"
    call :parse "%%~G" "%%~H" 
  ) else (
    for /F "tokens=1,2 delims=: " %%g in ("%~2") do (
      if /I "%%~g"=="transport_id" (
        set "_transport_id=%%~h"
      ) else (
        call :parse "%%~G" "%%~H" 
      )
    )
  )  
)
goto :eof

Проверено с использованием следующего сценария с жестко заданным гипотетическим выводом adb (без установки adb): 

@ECHO OFF
SETLOCAL EnableExtensions EnableDelayedExpansion
(
REM last token
set "_ID="&set "_transport_id="
call :parse "" "0123456789ABCDEF       device product:java_joyplus_qb7 model:TM702B4_3G device:java_joyplus_qb7 transport_id:12"
echo transport_id !_transport_id!  (!_ID!^)
REM penult token
set "_ID="&set "_transport_id="
call :parse "" "F9NPFP084096           device product:WW_P023 model:P023 transport_id:11 device:P023_1"
echo transport_id !_transport_id!  (!_ID!^)
REM elsewhere token
set "_ID="&set "_transport_id="
call :parse "" "abc123def567           transport_id:10 device product:XX_P023 model:P023 device:P023_2"
echo transport_id !_transport_id!  (!_ID!^)
REM nowhere token
set "_ID="&set "_transport_id="
call :parse "" "noTransportId          sport_id:10 device product:XX_P023 model:P023 device:P023_2"
echo transport_id !_transport_id!  (!_ID!^)
)
goto :eof

:parse
if "%~2"=="" goto :eof 
for /F "tokens=1,*" %%G in ("%~2") do (
  if "%~1"=="" (
    set "_ID=%%~G"
    call :parse "%%~G" "%%~H" 
  ) else (
    for /F "tokens=1,2 delims=: " %%g in ("%~2") do (
      if /I "%%~g"=="transport_id" (
        set "_transport_id=%%~h"
      ) else (
        call :parse "%%~G" "%%~H" 
      )
    )
  )  
)
goto :eof

Вывод : D:\bat\SO\61588773.bat

transport_id 12  (0123456789ABCDEF)
transport_id 11  (F9NPFP084096)
transport_id 10  (abc123def567)
transport_id   (noTransportId)
1 голос
/ 04 мая 2020

Вы можете легко извлечь все переменные независимо от их положения и показать, что вы хотите: 

@echo off
setlocal EnableDelayedExpansion

FOR /F "skip=1 delims=" %%a IN ('adb devices -l') DO (
   for %%b in (%%a) do for /F "tokens=1,2 delims=:" %%x in ("%%b") do set "%%x=%%y"

   echo Product=!product!
   echo Transport=!transport_id!
)

Например: 

Product=java_joyplus_qb7
Transport=12
Product=WW_P023
Transport=11
...