Как в подпрограмме Perl можно различать имена файлов, их имена, * DATA и * STDIN? - PullRequest
Новая
       27

Как в подпрограмме Perl можно различать имена файлов, их имена, * DATA и * STDIN?

5 голосов
/ 22 февраля 2010

Если у меня есть функция, которой может передаваться имя файла или различные файловые дескрипторы или typeglobs, как функция может различать эти аргументы, в том числе сообщать разницу, например, между *DATA и *STDIN?

Обновленный код, основанный на полученных ответах Спасибо всем. 

use strict;
use warnings;
use FileHandle;

sub file_thing_type {
    my ($f) = shift;
    my $type;
    my $r = ref $f;
    if ($r eq 'GLOB' or ref(\$f) eq 'GLOB'){
        # Regular and built-in file handles.
        my $fn = fileno $f;
        if (defined $fn){
            my %built_in = (
                'STDIN'  => fileno(*STDIN),
                'STDOUT' => fileno(*STDOUT),
                'STDERR' => fileno(*STDERR),
                'DATA'   => fileno(*DATA),
            );
            for my $k (keys %built_in){
                if (defined $built_in{$k} and $built_in{$k} == $fn){
                    $type = $k;
                    last;
                }
            }
            $type = 'regular file handle' unless defined $type;
        }
        else {
            $type = 'non-IO glob';
        }
    }
    elsif ($r){
        # A reference of some kind.
        $type = $r;
        # Might be an IO object. Has it been opened?
        {
            no warnings 'unopened';
            $type .= ' opened' if -f $f;
        }
    }
    else {
        # File name or just some other value?
        $type = -f $f ? 'file name' : 'other';
    }
    return $type;
}

open(my $h, '<', $0) or die $!;

printf "%12s => %s\n",
       $_->[0],
       file_thing_type($_->[1])
for (
    [ 'handle',     $h                  ], # regular file handle
    [ 'DATA',       *DATA               ], # DATA if source has DATA section; else non-IO glob
    [ 'STDIN',      *STDIN              ], # STDIN
    [ 'STDOUT',     *STDOUT             ], # STDOUT
    [ 'STDERR',     *STDERR             ], # STDERR
    [ 'FOO',        *FOO, *FOO          ], # non-IO glob
    [ 'FileHandle', FileHandle->new     ], # FileHandle
    [ 'FileHandle', FileHandle->new($0) ], # FileHandle opened
    [ 'file name',  $0                  ], # file name
    [ 'not file',   ''                  ], # other
    [ 'misc',       {bar=>1}            ], # HASH
);

__END__

Ответы [ 3 ]

2 голосов
/ 22 февраля 2010

Обновление: Проблема различения переменной, которая может быть назначена глобусам *DATA или *STDIN, - это задание для fileno: 

sub data_or_stdin {
  my $x = shift;
  if (fileno($x) == fileno(DATA)) {
    return "DATA";
  } elsif (fileno($x) == fileno(STDIN)) {
    return "STDIN";
  } else {
    return "NEITHER";
  }
}

print "DATA:  ", data_or_stdin(*DATA), "\n";
print "STDIN: ", data_or_stdin(*STDIN), "\n";
open(ZZZ, ">>", "zzz"); close ZZZ;
open(ZZZ, "<", "zzz"); print "ZZZ: ", data_or_stdin(*ZZZ), "\n"; close ZZZ;
open($fh, "<", "zzz"); print "\$fh=ZZZ: ", data_or_stdin($fh), "\n"; close $fh;
$fh = *DATA; print "\$fh=DATA: ", data_or_stdin($fh), "\n";
$fh = *STDIN; print "\$fh=STDIN: ", data_or_stdin($fh), "\n";

__END__
stuff;

$ perl data_or_stdin.pl
DATA:  DATA
STDIN: DATA
ZZZ: NEITHER
$fh=ZZZ: NEITHER
$fh=DATA: DATA
$fh=STDIN: DATA

Если $f - файловый дескриптор, то ref $f или ref \$f будет "GLOB" Если $f является скаляром, то ref \$f будет "SCALAR". 

sub filehandle_or_scalar {
  my $x = shift;
  if (ref $x eq "GLOB" || ref \$x eq "GLOB") {
      return "filehandle";
  } elsif (ref \$x eq "SCALAR") {
      return "scalar";
  } else {
      return "not filehandle or scalar";
  }
}

print "STDIN: ", filehandle_or_scalar(*STDIN), "\n";
print "\$_: ", filehandle_or_scalar($_), "\n";
open($fh, ">", "zzz");
print "\$fh: ", filehandle_or_scalar($fh), "\n";
print "string: ", filehandle_or_scalar('file.txt'), "\n";
print "ref: ", filehandle_or_scalar(\$x), "\n"

###########################################

$ perl filehandle_or_scalar.pl
STDIN: filehandle
$_: scalar
$fh: filehandle
string: scalar
ref: not filehandle or scalar
1 голос
/ 22 февраля 2010
Подход

Мобрула выглядит многообещающе: 

perl -E 'open $fh, "<", "/dev/null"; say ref $fh;'

выдаст GLOB. Тем не менее, так будет 

perl -E 'say ref \*FOO;'

«Настоящий» дескриптор файла также имеет дескриптор файла, связанный с это вы можете определить используя fileno: 

perl -MData::Dumper -E 'open $fh, "<", "/dev/null"; say Data::Dumper::Dumper([fileno $fh, fileno \*STDIN, fileno \*FOO])'

выведет что-то вроде: 

$VAR1 = [
          3,
          0,
          undef
        ];

Вы можете использовать это, чтобы указать GLOB, который используется для файлового ввода-вывода из тот, который не. В системах UNIX стандартный поток ввода связан с файловым дескриптором 0 по соглашению.

Еще одна вещь, которая приходит в голову, это класс, который привязан к указатель_на_файл. Это необходимо для реализации определенного интерфейса, который вы можно проверить на использование can. См. галстук ПЕРЕМЕННЫЙ, КЛАССИОН, СПИСОК введите в perlfunc подробности об этом интерфейсе.

1 голос
/ 22 февраля 2010

Вы можете использовать сопоставление с образцом в файловых дескрипторах строк для * STDIN, * DATA и т. Д ... 

if ($f =~ /\bSTDIN$/) {
    return "STDIN";
} elsif ($f =~ /\bDATA$/) {
    return "DATA";
}

Хаки, но может быть достаточно ...

...