Как глубоко сравнивать карты для фильтрации отдельных элементов в XQuery? - PullRequest
Новая
       49

Как глубоко сравнивать карты для фильтрации отдельных элементов в XQuery?

0 голосов
/ 11 июля 2020

I wi sh Я мог бы отфильтровать список карт, чтобы удалить те, которые идентичны.

Оператор union XQuery работает только на узлах.

Как я могу провести глубокое сравнение карт для вывода отдельных карт? Я могу предположить, что функция deep-equal() могла бы быть полезна там с функцией более высокого порядка, но я не мог с ней справиться. 

let $map1 := map{ 
  'a' : '1',
  'b' : '2'
}
let $map2 := map{ 
  'c' : '3',
  'd' : '4'
}
let $map3 := map{ 
  'a' : '1',
  'b' : '2'
}
return local:getDistinctMap( ($map1, $map2, $map3) )

Это должно вернуть 

map{ 
  'a' : '1',
  'b' : '2'
}
map{ 
  'c' : '3',
  'd' : '4'
}

1 Ответ

1 голос
/ 11 июля 2020

Вы можете использовать fold-left: 

declare function local:getDistinctMaps($maps as map(*)*) as map(*)* {
  fold-left(
    $maps, 
    (),
    function($distinct-maps, $new-map) { 
      if (some $map in $distinct-maps satisfies deep-equal($map, $new-map))
      then $distinct-maps else ($distinct-maps, $new-map)
    }
  )
};

let $map1 := map{ 
  'a' : '1',
  'b' : '2'
}
let $map2 := map{ 
  'c' : '3',
  'd' : '4'
}
let $map3 := map{ 
  'a' : '1',
  'b' : '2'
}
return local:getDistinctMaps( ($map1, $map2, $map3) )
...