Как построить диаграмму рассеяния на основе значений столбца в наборе данных?

Question

Мне предоставляется набор данных, который выглядит примерно так:

, и я пытаюсь построить график всех точек с 1 на первом столбец отделен от точек с 0, но я хочу поместить их в ту же диаграмму.

Я знаю, что окончательный результат должен быть примерно таким

Но я не могу найти способ отфильтровать точки в Julia. Я использую LinearAlgebra, CSV, Plots, DataFrames для своего проекта, и до сих пор я не нашел способа заставить типы хранения DataFrames хорошо работать с функциями Plots. Я продолжаю сталкиваться с такими ошибками, как Cannot convert Float64 to series data for plotting, когда пытаюсь построить точки индивидуально с помощью фильтра для l oop, как показано в приведенном ниже коде

filter = select(data, :1)
newData = select(data, 2:3)

#graph one initial point to create the plot
plot(newData[1,1], newData[1,2], seriestype = :scatter, title = "My Scatter Plot")

#add the additional points with the 1 in front
for i in 2:size(newData)
    if filter[i] == 1
        plot!(newData[i, 1], newData[i, 2], seriestype = :scatter, title = "My Scatter Plot")
    end
end

Другие подходы дали мне другие ошибки, но Я не записывал их.

Я использую Julia 1.4.0 и последние версии всех упомянутых пакетов.

Быстрое редактирование:

Может быть полезно знать, что я пытаюсь воспроизвести раздел этой статьи о нелинейном уменьшении размерности https://sebastianraschka.com/Articles/2014_kernel_pca.html#principal -компонент-анализ

Answer 1

С помощью Plots.jl вы можете сделать следующее (я передаю полностью воспроизводимый код):

julia> df = DataFrame(c=rand(Bool, 100), x = 2 .* rand(100) .- 1);

julia> df.y = ifelse.(df.c, 1, -1) .* df.x .^ 2;

julia> plot(df.x, df.y, color=ifelse.(df.c, "blue", "red"), seriestype=:scatter, legend=nothing)

Однако в этом случае я бы дополнительно использовал StatsPlots.jl, так как тогда вы можете просто написать:

julia> using StatsPlots

julia> @df df plot(:x, :y, group=:c, seriestype=:scatter, legend=nothing)

Если вы хотите сделать это вручную по группам, проще всего использовать функцию groupby:

julia> gdf = groupby(df, :c);

julia> summary(gdf) # check that we have 2 groups in data
"GroupedDataFrame with 2 groups based on key: c"

julia> plot(gdf[1].x, gdf[1].y, seriestype=:scatter, legend=nothing)

julia> plot!(gdf[2].x, gdf[2].y, seriestype=:scatter)

Обратите внимание, что переменная gdf привязана к GroupedDataFrame объект, из которого вы можете получить группы, определенные столбцом группировки (:c) в этом случае.