Показать все ветви-потомки первого уровня с помощью Git - PullRequest
Новая
       10

Показать все ветви-потомки первого уровня с помощью Git

8 голосов
/ 05 февраля 2010

Как я могу получить список ветвей, которые являются потомками первого уровня текущей HEAD?

Я могу получить список всего дерева с помощью: 

git log --graph --abbrev-commit --pretty=decorate --branches

, что дает 

* 2eff4a7... (refs/heads/issue-8351) Added a factory factory factory.
* 2e387aa... Refactored all of the factory factories.
| * b3fad52... (refs/heads/issue-8354) Moved the baz out of the constructor.
|/
| * f4cf3fe... (refs/heads/experimental) quuz looking good
| * 1d276b9... Risky fix to replace the quux with the quuz.
| * d6b0222... (refs/heads/issue-7559) Fixed the quux in the foo.
|/
| * 3f4cfff... (refs/heads/dev) wip
|/
* 76f493f... (refs/heads/master) SVN 30192

но я бы хотел получить простой список дочерних элементов первого уровня текущей ветви, как в этом примере для master: 

dev
issue-7559
issue-8354
issue-8351

и если бы я был на ветке issue-7559 я бы только увидел: 

experimental

Как я могу поступить об этом?

1 Ответ

3 голосов
/ 06 февраля 2010

Вы можете сделать это следующим образом.

Первая обычная преамбула: 

#! /usr/bin/perl

use warnings;
use strict;

Используйте git for-each-ref, чтобы собрать SHA-1 и название для каждой ссылки: 

sub refs {
  open my $fh, "-|", "git", "for-each-ref",
                            "--format=%(objectname)\t%(refname:short)"
    or die "$0: failed to run git for-each-ref";

  my %ref2sha;
  while (<$fh>) {
    chomp;
    my($sha,$ref) = split /\t/;
    $ref2sha{$ref} = $sha;
  }

  \%ref2sha;
}

Если коммит является дочерним по отношению к HEAD, набор коммитов, достижимых с HEAD, исключая все достижимые из рассматриваемого коммита, является пустым набором. Мы можем проверить эти отношения с git rev-list. 

sub is_child {
  my($ref) = @_;

  # git rev-list ^dev master
  my $refs = `git rev-list ^$ref HEAD -- 2>&1`;
  die "$0: git rev-list-failed.\n$refs" if $?;

  $refs !~ /\S/;
}

Для каждого ссылки, которая является потомком HEAD, но не эквивалентна HEAD, мы исследуем путь от HEAD к этой ссылке, используя git log. Если путь содержит кончик другой ветви, ссылка не может быть дочерним элементом первого уровня.

Все выжившие в этой перчатке - дети первого уровня. 

chomp(my $head = `git rev-parse HEAD 2>&1`);
die "$0: git rev-parse failed.\n$head" if $?;

my $ref2sha = refs;
my %headsha = reverse %$ref2sha;

REF:
foreach my $ref (keys %$ref2sha) {
  my $refsha = $ref2sha->{$ref};

  next if $refsha eq $head || !is_child $ref;

  my @log = `git log --pretty=format:%H ..$ref 2>&1`;
  die "$0: git log failed.\n@log" if $?;
  for (@log) {
    chomp;
    next if $_ eq $refsha;
    next REF if exists $headsha{$_};
  }

  print $ref, "\n";
}
...