Добавить все строки из нескольких книг в один шаблон книги

Question

У меня есть несколько книг с одинаковой структурой, 1-я строка заголовка и n строк данных / текста (всего у меня 5 столбцов, n отличается от книги к книге). Я ищу код, который может взять все данные книг и объединить их в одну книгу Excel с 1 строкой заголовка, а затем (nx количество книг) строк. У вас есть представление о коде, который делает что-то подобное? Спасибо.

Я использую здесь этот код:

Sub Basic_Example_1()
    Dim MyPath As String, FilesInPath As String
    Dim MyFiles() As String
    Dim SourceRcount As Long, Fnum As Long
    Dim mybook As Workbook, BaseWks As Worksheet
    Dim sourceRange As Range, destrange As Range
    Dim rnum As Long, CalcMode As Long

    'Fill in the path\folder where the files are
    MyPath = "C:\Users\myfolder\comments"

    'Add a slash at the end if the user forget it
    If Right(MyPath, 1) <> "\" Then
        MyPath = MyPath & "\"
    End If

    'If there are no Excel files in the folder exit the sub
    FilesInPath = Dir(MyPath & "*.xl*")
    If FilesInPath = "" Then
        MsgBox "No files found"
        Exit Sub
    End If

    'Fill the array(myFiles)with the list of Excel files in the folder
    Fnum = 0
    Do While FilesInPath <> ""
        Fnum = Fnum + 1
        ReDim Preserve MyFiles(1 To Fnum)
        MyFiles(Fnum) = FilesInPath
        FilesInPath = Dir()
    Loop

    'Change ScreenUpdating, Calculation and EnableEvents
    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    'Add a new workbook with one sheet
    Set BaseWks = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
    rnum = 1

    'Loop through all files in the array(myFiles)
    If Fnum > 0 Then
        For Fnum = LBound(MyFiles) To UBound(MyFiles)
            Set mybook = Nothing
            On Error Resume Next
            Set mybook = Workbooks.Open(MyPath & MyFiles(Fnum))
            On Error GoTo 0

            If Not mybook Is Nothing Then

                On Error Resume Next

                With mybook.Worksheets(1)
                    Set sourceRange = .Range("A2:G10")
                End With

                If Err.Number > 0 Then
                    Err.Clear
                    Set sourceRange = Nothing
                Else
                    'if SourceRange use all columns then skip this file
                    If sourceRange.Columns.Count >= BaseWks.Columns.Count Then
                        Set sourceRange = Nothing
                    End If
                End If
                On Error GoTo 0

                If Not sourceRange Is Nothing Then

                    SourceRcount = sourceRange.Rows.Count

                    If rnum + SourceRcount >= BaseWks.Rows.Count Then
                        MsgBox "Sorry there are not enough rows in the sheet"
                        BaseWks.Columns.AutoFit
                        mybook.Close savechanges:=False
                        GoTo ExitTheSub
                    Else

                        'Copy the file name in column A
                        With sourceRange
                            BaseWks.Cells(rnum, "A"). _
                                    Resize(.Rows.Count).Value = MyFiles(Fnum)
                        End With

                        'Set the destrange
                        Set destrange = BaseWks.Range("B" & rnum)

                        'we copy the values from the sourceRange to the destrange
                        With sourceRange
                            Set destrange = destrange. _
                                            Resize(.Rows.Count, .Columns.Count)
                        End With
                        destrange.Value = sourceRange.Value

                        rnum = rnum + SourceRcount
                    End If
                End If
                mybook.Close savechanges:=False
            End If

        Next Fnum
        BaseWks.Columns.AutoFit
    End If

ExitTheSub:
    'Restore ScreenUpdating, Calculation and EnableEvents
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With
End Sub

Но здесь я вручную ввожу диапазон A2: G10, проблема с этим подходом заключается в том, что я получаю недостающие строки, если рабочий лист имеет менее 10 рядов. Мне нужно было написать A2: G (посчитать последнюю строку).

Я нашел здесь код: https://www.rondebruin.nl/win/s3/win008.htm

Answer 1

Этот woulb будет улучшенным способом выполнения кода, который вы разместили:

Option Explicit
Sub Basic_Example_1()

    MemorySave True

    'Fill in the path\folder where the files are
    Dim MyPath As String: MyPath = "C:\Users\myfolder\comments\"
    'you can add the slash when defining the path.

    'If there are no Excel files in the folder exit the sub
    Dim FilesInPath As String: FilesInPath = Dir(MyPath & "*.xl*")
    If FilesInPath = "" Then
        MsgBox "No files found"
        GoTo ExitSub
    End If

    'Add a new workbook with one sheet
    Dim BaseWks As Worksheet: Set BaseWks = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
    Dim BaseLastRow As Long: BaseLastRow = 1

    'Fill the array(myFiles)with the list of Excel files in the folder
    'Instead of filling an array, use this loop to import the rows
    Do While FilesInPath <> ""
        ImportData MyPath & FilesInPath, BaseWks
        BaseLastRow = BaseWks.Cells(Rows.Count, 1).End(xlUp).Row + 1
        FilesInPath = Dir()
    Loop

ExitSub:
    MemorySave False

End Sub
Private Sub ImportData(WorkbookPath As String, BaseWks As Worksheet, BaseLastRow As Long)

    'The first iteration will copy the headers, after that, it won't
    Dim FirstRow As Long
    If BaseLastRow = 1 Then
        FirstRow = 1
    Else
        FirstRow = 2
    End If

    Dim wb As Workbook: Set wb = Workbooks.Open(WorkbookPath, False, True)
    With wb.Sheets(1)

        'check the lastrow on the import workbook
        Dim LastRow As Long: LastRow = .Cells(.Rows.Count, 1).End(xlUp).Row

        'if the importworkbook has more than 1 row, then copy the Range A:G
        If LastRow > 1 Then
            .Range("A" & FirstRow & ":G" & LastRow).Copy
            BaseWks.Range("A" & BaseLastRow).PasteSpecial xlPasteValues
            Application.CutCopyMode = False
        End If

    End With

    'Close the importworkbook without saving
    wb.Close False

End Sub
Sub MemorySave(isOn As Boolean)
    Application.Calculation = IIf(isOn, xlCalculationManual, xlCalculationAutomatic)
    Application.EnableEvents = Not (isOn)
    Application.ScreenUpdating = Not (isOn)
    Application.DisplayAlerts = Not (isOn)
End Sub

Answer 2

С вашим обновленным вопросом и вариантом комментария Дамиана вы можете придумать следующее:

На этом этапе:

With mybook.Worksheets(1)
   Set sourceRange = .Range("A2:G10")
End With

Вы можете найти и использовать последнюю строку следующим образом:

With mybook.Worksheets(1)
   Set sourceRange = .Range("A2:G" & .Cells(.Rows.Count, "A").End(xlUp).Row)
End With