Разбивка растровых изображений на wxFrame - PullRequest
Новая
       72

Разбивка растровых изображений на wxFrame

1 голос
/ 28 мая 2020

Я хочу установить фон в кадре с мозаичными растровыми изображениями, используя wx Perl. С помощью примера из wxWidgets я придумал код ниже. К сожалению, ничего не делает, рамка остается пустой. Это вообще правильный способ сделать это или есть другой способ? 

use warnings;
use strict;

package MyFrame;
use Wx qw(:everything);
use base qw( Wx::Frame );

sub new {
    my ( $class, $path ) = @_;
    my $self
        = $class->SUPER::new( undef, -1, 'Test', [ -1, -1 ], [ 600, 400 ], );
    $self->set_tiling_background($path);
    return $self;
}

sub set_tiling_background {
    my ( $self, $path ) = @_;

    ## Create a wxBitmap from the file
    my $file = IO::File->new($path);
    binmode $file;

    my $handler = Wx::BMPHandler->new();
    my $image   = Wx::Image->new();
    $handler->LoadFile( $image, $file );
    my $bitmap = Wx::Bitmap->new($image);

    ## Just to check that the bitmap is good.
    $bitmap->SaveFile('saved.bmp', wxBITMAP_TYPE_BMP);

    ## Draw the bitmap tiling over the frame
    ## https://github.com/wxWidgets/wxWidgets/blob/master/src/html/htmlwin.cpp
    my $dc = Wx::WindowDC->new($self);

    my $size_x = $bitmap->GetWidth;
    my $size_y = $bitmap->GetHeight;

    for ( my $x = 0; $x < 600; $x += $size_x ) {
        for ( my $y = 0; $y < 400; $y += $size_y ) {
            $dc->DrawBitmap( $bitmap, $x, $y, 0 );
        }
    }
}

package MyApp;
use base 'Wx::App';
my $path = '/path/to/bitmap.bmp';

sub OnInit {
    my ($self) = @_;
    my $frame = MyFrame->new($path);
    $frame->Show(1);
}

package main;
MyApp->new->MainLoop;

Ответы [ 2 ]

2 голосов
/ 28 мая 2020

В принятом ответе уже объясняется, как это сделать правильно, но я также хотел бы объяснить, что вы сделали неправильно изначально: вы не можете нарисовать WindowDC только один раз и надеяться на sh что-нибудь сделать. Любое постоянное рисование должно выполняться на PaintDC в обработчике EVT_PAINT или, как особый вид исключения, на D C, предоставленном обработчику EVT_BACKGROUND_ERASE. Если вы настроите обработчик EVT_PAINT, вызывающий исходный set_tiling_background и использующий из него PaintDC, он тоже сработает.

Фактически, на современных платформах (GTK3, macOS) вы не сможете не используйте ни WindowDC, ни ClientDC, рисование на них просто не работает.

2 голосов
/ 28 мая 2020

Вот пример использования обработчика событий ERASE_BACKGROUND: 

package MyFrame;
use Wx qw(:everything wxBITMAP_TYPE_JPEG);
use base qw( Wx::Frame );
use feature qw(say);
use strict;
use warnings;
use Wx::Event;

sub new {
    my ( $class, $path ) = @_;
    my $self
        = $class->SUPER::new( undef, -1, 'Test', [ -1, -1 ], [ 600, 400 ], );
    my $bitmap = Wx::Bitmap->new( $path , wxBITMAP_TYPE_JPEG );
    Wx::Event::EVT_ERASE_BACKGROUND( $self, sub { $self->setBgImage( $bitmap, @_) });
    return $self;
}

sub setBgImage {
    my ( $self, $bitmap, $frame, $evt ) = @_;

    return if !defined $evt;
    my $dc = $evt->GetDC();
    my $size_x = $bitmap->GetWidth;
    my $size_y = $bitmap->GetHeight;

    for ( my $x = 0; $x < 600; $x += $size_x ) {
        for ( my $y = 0; $y < 400; $y += $size_y ) {
            $dc->DrawBitmap( $bitmap, $x, $y, 0 );
        }
    }
}

package MyApp;
use base 'Wx::App';
my $path = 'logo.jpg';

sub OnInit {
    my ($self) = @_;
    my $frame = MyFrame->new($path);
    $frame->Show(1);
}

package main;
MyApp->new->MainLoop;

Это дает мне следующий результат в Ubuntu 20.04:

enter image description here

См. Также: wx Python: Размещение фонового изображения на панели

...