Ошибка исключения в списках функций: foldl / 3 (lists.erl, строка 1263) - PullRequest
Новая
       83

Ошибка исключения в списках функций: foldl / 3 (lists.erl, строка 1263)

0 голосов
/ 12 июля 2020

Вопрос

Почему, когда я запускаю функцию, она работает, а когда я передаю ее на lists:foldl, она не работает?

Подробное объяснение

Когда я запускаю в терминале специальную функцию c, она возвращает ожидаемый результат. Но если я передаю эту функцию в lists: foldl, она выдает исключение.

Проблема c функция separate_socks/2.

Когда я запускаю ее напрямую, она возвращает: 

> sock_merchant:separate_socks(1, #{1 => [1]}).
#{1 => [1,1]}

> sock_merchant:separate_socks(1, #{}).        
#{1 => [1]}

Но когда я запускаю test/0, он возвращает: 

> sock_merchant:test().                        
** exception error: bad function separate_socks
     in function  lists:foldl/3 (lists.erl, line 1263)

Мой sock_merchant.erl файл имеет следующее содержимое: 

% John works at a clothing store. He has a large pile of socks that he must pair
% by color for sale. Given an array of integers representing the color of each
% sock, determine how many pairs of socks with matching colors there are.

% For example, there are `n = 7` socks with colors `ar = [1,2,1,2,1,3,2]`. There
% is one pair of color 1 and one of color 2. There are three odd socks left, one
% of each color. The number of pairs is 2.

-module(sock_merchant).

-export([count_number_of_pair_of_sockets/2,
         filter_socks/2,
         separate_socks/2,
         sock_merchant/2,
         test/0,
         test_sock_merchant/0]).

%% Next: number
%% Acc: map
separate_socks(Next, Acc) ->
    KeyExists = maps:is_key(Next, Acc),

    case KeyExists of
        true ->
            CurrentKeyList = maps:get(Next, Acc),
            maps:update(Next, [Next | CurrentKeyList], Acc);
        false -> maps:put(Next, [Next], Acc)
    end.

%% Value: number
filter_socks(_, Value) ->
    if Value div 2 >= 1 -> true;
       true -> false
    end.

%% Next: {key, [number]}
%% Acc: number
count_number_of_pair_of_sockets({_, Arr}, Acc) ->
    Acc + length(Arr) div 2.

%% N: number
%% Ar: [number]
sock_merchant(_, Ar) ->
    % SocksSeparatedList = #{1: [1,1], 2: [2], ...}
    SocksSeparatedList = lists:foldl(separate_socks,
                                     #{},
                                     Ar),
    SocksWithPairs = maps:filter(filter_socks,
                                 SocksSeparatedList),
    ListOfSocksWithPairs = maps:to_list(SocksWithPairs),
    lists:foldl(count_number_of_pair_of_sockets,
                0,
                ListOfSocksWithPairs).

test_sock_merchant() ->
    3 = sock_merchant(9,
                      [10, 20, 20, 10, 10, 30, 50, 10, 20]),
    pass.

test() -> pass = test_sock_merchant().

Я решение этой проблемы из HackerRank https://www.hackerrank.com/challenges/sock-merchant/problem?h_l=interview&playlist_slugs%5B%5D=interview-preparation-kit&playlist_slugs%5B%5D=warmup

1 Ответ

1 голос
/ 12 июля 2020

Термин separate_socks сам по себе является атомом. Это означает, что когда вы вызываете lists:foldl/3, передавая separate_socks в качестве первого аргумента, вы просто передаете атом, а не функцию, поскольку lists:foldl/3 требует: 

SocksSeparatedList = lists:foldl(separate_socks,
                                 #{},
                                 Ar),

Чтобы вместо этого передать функцию separate_socks, передайте его как термин функции: 

SocksSeparatedList = lists:foldl(fun separate_socks/2,
                                 #{},
                                 Ar),

Ключевое слово fun указывает на функцию, а завершающее /2 - это арность функции (количество ее аргументов).

...